tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 python3,
4 fetchFromGitLab,
5 fetchFromGitHub,
6}:
7let
8 python = python3.override {
9 packageOverrides = self: super: {
10 lark010 = super.lark.overridePythonAttrs (old: rec {
11 version = "0.10.0";
12
13 src = fetchFromGitHub {
14 owner = "lark-parser";
15 repo = "lark";
16 tag = version;
17 sha256 = "sha256-ctdPPKPSD4weidyhyj7RCV89baIhmuxucF3/Ojx1Efo=";
18 };
19
20 patches = [ ];
21
22 disabledTestPaths = [ "tests/test_nearley/test_nearley.py" ];
23 });
24 };
25 self = python;
26 };
27in
28python.pkgs.buildPythonApplication rec {
29 pname = "sca2d";
30 version = "0.2.2";
31 pyproject = true;
32
33 src = fetchFromGitLab {
34 owner = "bath_open_instrumentation_group";
35 repo = "sca2d";
36 tag = "v${version}";
37 hash = "sha256-p0Bv8jcnjcOLBAXN5A4GspSIEG4G4NPA4o0aEtwe/LU=";
38 };
39
40 build-system = with python.pkgs; [ setuptools ];
41
42 dependencies = with python.pkgs; [
43 lark010
44 colorama
45 ];
46
47 pythonImportsCheck = [ "sca2d" ];
48
49 meta = {
50 description = "Experimental static code analyser for OpenSCAD";
51 mainProgram = "sca2d";
52 homepage = "https://gitlab.com/bath_open_instrumentation_group/sca2d";
53 changelog = "https://gitlab.com/bath_open_instrumentation_group/sca2d/-/blob/v${version}/CHANGELOG.md";
54 license = lib.licenses.gpl3Only;
55 maintainers = with lib.maintainers; [ traxys ];
56 };
57}