tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitea,
5
6 pkg-config,
7 cmake,
8 ninja,
9 spirv-tools,
10 qt6,
11 breakpad,
12 jemalloc,
13 cli11,
14 wayland,
15 wayland-protocols,
16 wayland-scanner,
17 libxcb,
18 libdrm,
19 libgbm,
20 pipewire,
21 pam,
22}:
23stdenv.mkDerivation (finalAttrs: {
24 pname = "quickshell";
25 version = "0.2.1";
26
27 # github mirror: https://github.com/quickshell-mirror/quickshell
28 src = fetchFromGitea {
29 domain = "git.outfoxxed.me";
30 owner = "quickshell";
31 repo = "quickshell";
32 tag = "v${finalAttrs.version}";
33 hash = "sha256-e++Ogy91Sv7gGLMdAqZaBzbH/UmPWZ4GAt7VDCA66aU=";
34 };
35
36 nativeBuildInputs = [
37 cmake
38 ninja
39 qt6.qtshadertools
40 spirv-tools
41 wayland-scanner
42 qt6.wrapQtAppsHook
43 pkg-config
44 ];
45
46 buildInputs = [
47 qt6.qtbase
48 qt6.qtdeclarative
49 qt6.qtwayland
50 qt6.qtsvg
51 cli11
52 wayland
53 wayland-protocols
54 libdrm
55 libgbm
56 breakpad
57 jemalloc
58 libxcb
59 pam
60 pipewire
61 ];
62
63 cmakeFlags = [
64 (lib.cmakeFeature "DISTRIBUTOR" "Nixpkgs")
65 (lib.cmakeBool "DISTRIBUTOR_DEBUGINFO_AVAILABLE" true)
66 (lib.cmakeFeature "INSTALL_QML_PREFIX" qt6.qtbase.qtQmlPrefix)
67 (lib.cmakeFeature "GIT_REVISION" "tag-v${finalAttrs.version}")
68 ];
69
70 cmakeBuildType = "RelWithDebInfo";
71 separateDebugInfo = true;
72 dontStrip = false;
73
74 meta = {
75 homepage = "https://quickshell.org";
76 description = "Flexbile QtQuick based desktop shell toolkit";
77 license = lib.licenses.lgpl3Only;
78 platforms = lib.platforms.linux;
79 mainProgram = "quickshell";
80 maintainers = with lib.maintainers; [ outfoxxed ];
81 };
82})