tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 python3,
4 fetchPypi,
5 copyDesktopItems,
6 libsForQt5,
7 makeDesktopItem,
8}:
9
10let
11 inherit (libsForQt5)
12 qtsvg
13 wrapQtAppsHook
14 ;
15in
16python3.pkgs.buildPythonApplication (finalAttrs: {
17 format = "setuptools";
18 pname = "pyspread";
19 version = "2.4";
20 src = fetchPypi {
21 pname = "pyspread";
22 inherit (finalAttrs) version;
23 hash = "sha256-MZlR2Rap5oMRfCmswg9W//FYFkSEki7eyMNhLoGZgJM=";
24 };
25
26 nativeBuildInputs = [
27 copyDesktopItems
28 wrapQtAppsHook
29 ];
30
31 buildInputs = [
32 qtsvg
33 ];
34
35 propagatedBuildInputs = with python3.pkgs; [
36 python-dateutil
37 markdown2
38 matplotlib
39 numpy
40 pyenchant
41 pyqt5
42 setuptools
43 ];
44
45 strictDeps = true;
46
47 doCheck = false; # it fails miserably with a core dump
48
49 pythonImportsCheck = [ "pyspread" ];
50
51 desktopItems = [
52 (makeDesktopItem {
53 name = "pyspread";
54 exec = "pyspread";
55 icon = "pyspread";
56 desktopName = "Pyspread";
57 genericName = "Spreadsheet";
58 comment = "A Python-oriented spreadsheet application";
59 categories = [
60 "Office"
61 "Development"
62 "Spreadsheet"
63 ];
64 })
65 ];
66
67 preFixup = ''
68 makeWrapperArgs+=("''${qtWrapperArgs[@]}")
69 '';
70
71 meta = {
72 homepage = "https://pyspread.gitlab.io/";
73 description = "Python-oriented spreadsheet application";
74 longDescription = ''
75 pyspread is a non-traditional spreadsheet application that is based on and
76 written in the programming language Python. The goal of pyspread is to be
77 the most pythonic spreadsheet.
78
79 pyspread expects Python expressions in its grid cells, which makes a
80 spreadsheet specific language obsolete. Each cell returns a Python object
81 that can be accessed from other cells. These objects can represent
82 anything including lists or matrices.
83 '';
84 license = with lib.licenses; [ gpl3Plus ];
85 mainProgram = "pyspread";
86 maintainers = [ ];
87 };
88})