tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 alsa-lib,
6 qt5,
7}:
8
9let
10 inherit (qt5)
11 qmake
12 wrapQtAppsHook
13 qtgraphicaleffects
14 qtquickcontrols2
15 ;
16in
17stdenv.mkDerivation (finalAttrs: {
18 pname = "opensoundmeter";
19 version = "1.5.2";
20
21 src = fetchFromGitHub {
22 owner = "psmokotnin";
23 repo = "osm";
24 rev = "v${finalAttrs.version}";
25 hash = "sha256-jM9tkfNjPNHcPOG0n7NeohC/O3E6CUspOF3UTkQ2rs8=";
26 };
27
28 patches = [ ./build.patch ];
29
30 postPatch = ''
31 substituteInPlace OpenSoundMeter.pro \
32 --replace 'APP_GIT_VERSION = ?' 'APP_GIT_VERSION = ${finalAttrs.src.rev}'
33 '';
34
35 nativeBuildInputs = [
36 qmake
37 wrapQtAppsHook
38 ];
39
40 buildInputs = [
41 alsa-lib
42 qtgraphicaleffects
43 qtquickcontrols2
44 ];
45
46 installPhase = ''
47 runHook preInstall
48
49 install OpenSoundMeter -Dt $out/bin
50 install OpenSoundMeter.desktop -m444 -Dt $out/share/applications
51 install icons/white.png -m444 -D $out/share/icons/OpenSoundMeter.png
52
53 runHook postInstall
54 '';
55
56 meta = {
57 description = "Sound measurement application for tuning audio systems in real-time";
58 homepage = "https://opensoundmeter.com/";
59 license = lib.licenses.gpl3Plus;
60 mainProgram = "OpenSoundMeter";
61 maintainers = [ ];
62 platforms = lib.platforms.linux;
63 };
64})