tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchzip,
5 testers,
6 autoreconfHook,
7 pkg-config,
8 glib,
9 dbus,
10 ell,
11 systemd,
12 bluez,
13 mobile-broadband-provider-info,
14 python3,
15}:
16
17stdenv.mkDerivation (finalAttrs: {
18 pname = "ofono";
19 version = "2.19";
20
21 outputs = [
22 "out"
23 "dev"
24 ];
25
26 src = fetchzip {
27 url = "https://git.kernel.org/pub/scm/network/ofono/ofono.git/snapshot/ofono-${finalAttrs.version}.tar.gz";
28 hash = "sha256-OFoEl4Ve5DCNYsDfQpO26tZQTUz1192v0oECsXvHTG8=";
29 };
30
31 patches = [ ./0001-Search-connectors-in-OFONO_PLUGIN_PATH.patch ];
32
33 postPatch = ''
34 patchShebangs tools/provisiontool
35 '';
36
37 strictDeps = true;
38
39 nativeBuildInputs = [
40 autoreconfHook
41 pkg-config
42 python3
43 ];
44
45 buildInputs = [
46 glib
47 dbus
48 ell
49 systemd
50 bluez
51 mobile-broadband-provider-info
52 ];
53
54 configureFlags = [
55 (lib.strings.withFeatureAs true "dbusconfdir" "${placeholder "out"}/share")
56 (lib.strings.withFeatureAs true "systemdunitdir" "${placeholder "out"}/lib/systemd/system")
57 (lib.strings.enableFeature true "external-ell")
58 "--sysconfdir=/etc"
59 ];
60
61 installFlags = [ "sysconfdir=${placeholder "out"}/etc" ];
62
63 enableParallelBuilding = true;
64 enableParallelChecking = false;
65
66 doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
67
68 passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
69
70 meta = {
71 description = "Infrastructure for building mobile telephony (GSM/UMTS) applications";
72 homepage = "https://git.kernel.org/pub/scm/network/ofono/ofono.git";
73 changelog = "https://git.kernel.org/pub/scm/network/ofono/ofono.git/plain/ChangeLog?h=${finalAttrs.version}";
74 license = lib.licenses.gpl2Only;
75 maintainers = [ ];
76 platforms = lib.platforms.linux;
77 mainProgram = "ofonod";
78 pkgConfigModules = [
79 "ofono"
80 ];
81 };
82})