tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 buildNimPackage,
4 fetchFromGitHub,
5 nixosTests,
6 replaceVars,
7 unstableGitUpdater,
8}:
9
10buildNimPackage (
11 finalAttrs: prevAttrs: {
12 pname = "nitter";
13 version = "0-unstable-2025-12-24";
14
15 src = fetchFromGitHub {
16 owner = "zedeus";
17 repo = "nitter";
18 rev = "a92e79ebc3581702dc427434a782a5fc1d28cc91";
19 hash = "sha256-bCogvVO99HPiZZOMDd0IDBNGBKIZ+My493SnbK+6HxM=";
20 };
21
22 lockFile = ./lock.json;
23
24 patches = [
25 (replaceVars ./nitter-version.patch {
26 inherit (finalAttrs) version;
27 inherit (finalAttrs.src) rev;
28 url = builtins.replaceStrings [ "archive" ".tar.gz" ] [ "commit" "" ] finalAttrs.src.url;
29 })
30 ];
31
32 postBuild = ''
33 nim compile ${toString finalAttrs.nimFlags} -r tools/gencss
34 nim compile ${toString finalAttrs.nimFlags} -r tools/rendermd
35 '';
36
37 postInstall = ''
38 mkdir -p $out/share/nitter
39 cp -r public $out/share/nitter/public
40 '';
41
42 passthru = {
43 tests = { inherit (nixosTests) nitter; };
44 updateScript = unstableGitUpdater { };
45 };
46
47 meta = {
48 homepage = "https://github.com/zedeus/nitter";
49 description = "Alternative Twitter front-end";
50 license = lib.licenses.agpl3Only;
51 maintainers = with lib.maintainers; [
52 erdnaxe
53 infinidoge
54 ];
55 mainProgram = "nitter";
56 };
57 }
58)