tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 gitUpdater,
6}:
7
8stdenv.mkDerivation (finalAttrs: {
9 pname = "liquidprompt";
10 version = "2.2.1";
11
12 src = fetchFromGitHub {
13 owner = "liquidprompt";
14 repo = "liquidprompt";
15 rev = "v${finalAttrs.version}";
16 hash = "sha256-ZVzFGe3ItWsN23iyGpxZEN2KtviYKI8x/sDa2MRio/Y=";
17 };
18
19 strictDeps = true;
20
21 postPatch = ''
22 patchShebangs tools/*.sh
23 '';
24
25 installPhase = ''
26 runHook preInstall
27
28 install -D -m 0444 liquidprompt $out/bin/liquidprompt
29
30 install -D -m 0444 liquidprompt.plugin.zsh \
31 $out/share/zsh/plugins/liquidprompt/liquidprompt.plugin.zsh
32 install -D -m 0444 liquidprompt \
33 $out/share/zsh/plugins/liquidprompt/liquidprompt
34
35 # generate default config file
36 mkdir -p $out/share/doc/liquidprompt
37 tools/config-from-doc.sh --verbose > $out/share/doc/liquidprompt/liquidpromptrc-dist
38
39 mkdir -p $out/share/liquidprompt
40 cp -a themes $out/share/liquidprompt/
41
42 mkdir -p $out/share/liquidprompt/contrib
43 cp -a contrib/presets $out/share/liquidprompt/contrib/
44
45 runHook postInstall
46 '';
47
48 passthru.updateScript = gitUpdater { };
49
50 meta = {
51 description = "Full-featured & carefully designed adaptive prompt for Bash & Zsh";
52 homepage = "https://github.com/liquidprompt/liquidprompt";
53 license = lib.licenses.agpl3Plus;
54 platforms = lib.platforms.all;
55 maintainers = with lib.maintainers; [ gerschtli ];
56 };
57})