tjh.dev
1{
2 lib,
3 stdenvNoCC,
4 appimageTools,
5 fetchurl,
6 pname,
7 version,
8 meta,
9}:
10
11let
12 suffix =
13 {
14 aarch64-linux = "linux-armv7l";
15 x86_64-linux = "linux-x86_64";
16 i686-linux = "linux-i386";
17 }
18 .${stdenvNoCC.hostPlatform.system}
19 or (throw "Unsupported system: ${stdenvNoCC.hostPlatform.system}");
20in
21appimageTools.wrapType2 rec {
22 inherit pname version;
23
24 src = fetchurl {
25 url = "https://hamrs-releases.s3.us-east-2.amazonaws.com/${version}/hamrs-${version}-${suffix}.AppImage";
26 hash =
27 {
28 aarch64-linux = "sha256-nBW8q7LVWQz93LkTc+c36H+2ymLLwLKfxePUwEm3D2E=";
29 x86_64-linux = "sha256-tplp7TADvbxkk5qBb4c4zm4mrzrVtW/WVUjiolBBJHc=";
30 i686-linux = "sha256-PllxLMBsPCedKU7OUN0nqi4qtQ57l2Z+huLfkfaBfT4=";
31 }
32 .${stdenvNoCC.hostPlatform.system}
33 or (throw "Unsupported system: ${stdenvNoCC.hostPlatform.system}");
34 };
35
36 extraInstallCommands =
37 let
38 contents = appimageTools.extract { inherit pname version src; };
39 in
40 ''
41 install -m 444 -D ${contents}/${pname}.desktop -t $out/share/applications
42 substituteInPlace $out/share/applications/${pname}.desktop \
43 --replace-fail 'Exec=AppRun' 'Exec=${pname}'
44 cp -r ${contents}/usr/share/icons $out/share
45 '';
46
47 inherit meta;
48}