tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 cfitsio,
6}:
7
8stdenv.mkDerivation (finalAttrs: {
9 pname = "fitsverify";
10 version = "4.22";
11
12 src = fetchurl {
13 url = "https://heasarc.gsfc.nasa.gov/docs/software/ftools/fitsverify/fitsverify-${finalAttrs.version}.tar.gz";
14 hash = "sha256-bEXoA6fg7by30TkYYVuuY2HSszPCkrhJxQnsm+vbGLQ=";
15 };
16
17 buildInputs = [
18 cfitsio
19 ];
20
21 # See build instructions in the README file in src.
22 buildPhase = ''
23 $CC -o fitsverify ftverify.c fvrf_data.c fvrf_file.c fvrf_head.c \
24 fvrf_key.c fvrf_misc.c -DSTANDALONE \
25 $NIX_CFLAGS_COMPILE \
26 -lcfitsio
27 '';
28
29 installPhase = ''
30 install -D fitsverify $out/bin/fitsverify
31 '';
32
33 meta = {
34 description = "FITS File Format-Verification Tool";
35 mainProgram = "fitsverify";
36 longDescription = ''
37 Fitsverify is a computer program that rigorously checks whether a FITS
38 (Flexible Image Transport System) data file conforms to all the
39 requirements defined in Version 3.0 of the FITS Standard document.
40 '';
41 homepage = "https://heasarc.gsfc.nasa.gov/docs/software/ftools/fitsverify/";
42 license = lib.licenses.mit;
43 platforms = with lib.platforms; linux;
44 maintainers = with lib.maintainers; [ panicgh ];
45 };
46})