tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenvNoCC,
4 fetchFromGitHub,
5 callPackage,
6 nixosTests,
7 nix-update-script,
8}:
9
10stdenvNoCC.mkDerivation (finalAttrs: {
11 pname = "fider";
12 version = "0.27.0";
13
14 src = fetchFromGitHub {
15 owner = "getfider";
16 repo = "fider";
17 tag = "v${finalAttrs.version}";
18 hash = "sha256-2aV6f4cgO89hIqksT/kutR+ZRTGncuS04kJ5xZZC5Ds=";
19 };
20
21 dontConfigure = true;
22 dontBuild = true;
23
24 # Allow easier version overrides, e.g.:
25 # pkgs.fider.overrideAttrs (prev: {
26 # version = "...";
27 # src = prev.src.override {
28 # hash = "...";
29 # };
30 # vendorHash = "...";
31 # npmDepsHash = "...";
32 # })
33 vendorHash = "sha256-4ilOdUblpwteY0ZInitSuzuB8mU1ltYgRJjla6LiziU=";
34 npmDepsHash = "sha256-c8CFMMmFcLZkJL50bfLlk2HP9B/rexNZ2WWJkV0x4Rk=";
35
36 server = callPackage ./server.nix {
37 inherit (finalAttrs)
38 pname
39 version
40 src
41 vendorHash
42 ;
43 };
44 frontend = callPackage ./frontend.nix {
45 inherit (finalAttrs)
46 pname
47 version
48 src
49 npmDepsHash
50 ;
51 };
52
53 installPhase = ''
54 runHook preInstall
55
56 mkdir -p $out/etc
57 cp -r locale views migrations $out/
58 cp -r etc/*.md $out/etc/
59 ln -s ${finalAttrs.server}/* $out/
60 ln -s ${finalAttrs.frontend}/* $out/
61
62 runHook postInstall
63 '';
64
65 passthru = {
66 tests = {
67 inherit (nixosTests) fider;
68 };
69 updateScript = nix-update-script { };
70 };
71
72 meta = {
73 description = "Open platform to collect and prioritize feedback";
74 homepage = "https://github.com/getfider/fider";
75 changelog = "https://github.com/getfider/fider/releases/tag/${finalAttrs.src.tag}";
76 license = lib.licenses.agpl3Only;
77 mainProgram = "fider";
78 maintainers = with lib.maintainers; [
79 niklaskorz
80 ];
81 };
82})