tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 stdenv,
3 lib,
4 fetchFromGitHub,
5 makeWrapper,
6 perlPackages,
7 cursesSupport ? true,
8 uriFindSupport ? true,
9}:
10
11let
12 perlDeps = [
13 perlPackages.MIMETools
14 perlPackages.HTMLParser
15 ]
16 ++ lib.optional cursesSupport perlPackages.CursesUI
17 ++ lib.optional uriFindSupport perlPackages.URIFind;
18
19in
20stdenv.mkDerivation (finalAttrs: {
21 pname = "extract_url";
22 version = "1.6.2";
23
24 src = fetchFromGitHub {
25 owner = "m3m0ryh0l3";
26 repo = "extracturl";
27 rev = "v${finalAttrs.version}";
28 sha256 = "05589lp15jmcpbj4y9a3hmf6n2gsqrm4ybcyh3hd4j6pc7hmnhny";
29 };
30
31 nativeBuildInputs = [ makeWrapper ];
32 buildInputs = [ perlPackages.perl ] ++ perlDeps;
33
34 makeFlags = [ "prefix=$(out)" ];
35 installFlags = [ "INSTALL=install" ];
36
37 postFixup = ''
38 wrapProgram "$out/bin/extract_url" \
39 --set PERL5LIB "${perlPackages.makeFullPerlPath perlDeps}"
40 '';
41
42 meta = {
43 homepage = "https://www.memoryhole.net/~kyle/extract_url/";
44 description = "Extracts URLs from MIME messages or plain text";
45 mainProgram = "extract_url";
46 license = lib.licenses.bsd2;
47 maintainers = [ lib.maintainers.qyliss ];
48 platforms = lib.platforms.unix;
49 };
50})