tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 rustPlatform,
5 fetchFromGitHub,
6 just,
7 libcosmicAppHook,
8 pciutils,
9 usbutils,
10 util-linux,
11 nix-update-script,
12}:
13rustPlatform.buildRustPackage (finalAttrs: {
14 pname = "examine";
15 version = "2.0.0";
16
17 src = fetchFromGitHub {
18 owner = "cosmic-utils";
19 repo = "examine";
20 tag = finalAttrs.version;
21 hash = "sha256-6U8reOzeqamX/MG/mWbso+kjuZQ6cK8j9XhuEtGZ1q4=";
22 };
23
24 cargoHash = "sha256-V+ClzaG7LnkOl84j5mVGJPTLVfaVqxaSH7ufmjXdwyM=";
25
26 nativeBuildInputs = [
27 just
28 libcosmicAppHook
29 ];
30
31 dontUseJustBuild = true;
32 dontUseJustCheck = true;
33
34 justFlags = [
35 "--set"
36 "prefix"
37 (placeholder "out")
38 "--set"
39 "bin-src"
40 "target/${stdenv.hostPlatform.rust.cargoShortTarget}/release/examine"
41 ];
42
43 preFixup = ''
44 libcosmicAppWrapperArgs+=(--prefix PATH : ${
45 lib.makeBinPath [
46 pciutils
47 usbutils
48 util-linux
49 ]
50 })
51 '';
52
53 env.VERGEN_GIT_SHA = finalAttrs.version;
54
55 passthru.updateScript = nix-update-script { };
56
57 meta = {
58 changelog = "https://github.com/cosmic-utils/examine/releases/tag/${finalAttrs.version}";
59 description = "System information viewer for the COSMIC Desktop";
60 homepage = "https://github.com/cosmic-utils/examine";
61 license = lib.licenses.gpl3Only;
62 mainProgram = "examine";
63 maintainers = with lib.maintainers; [ HeitorAugustoLN ];
64 platforms = lib.platforms.linux;
65 sourceProvenance = [ lib.sourceTypes.fromSource ];
66 };
67})