tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitLab,
5
6 # nativeBuildInputs
7 protobuf,
8 qt5,
9 libsForQt5,
10 pkg-config,
11 installShellFiles,
12
13 # buildInputs
14 ghostscript,
15 poppler-utils,
16 exempi,
17}:
18
19stdenv.mkDerivation (finalAttrs: {
20 pname = "equalx";
21 version = "0.7.1-unstable-2020-02-26";
22
23 src = fetchFromGitLab {
24 owner = "q-quark";
25 repo = "equalx";
26 rev = "b7175a574379d86c43cabbdb6071f0b6d40d8e79";
27 hash = "sha256-3KIJk5bTmFjaojjHDurJjEgyvuIf0LHcSi+MrmsRPcg=";
28 };
29 postPatch = ''
30 substituteInPlace equalx.pro \
31 --replace-fail 'git describe --abbrev=0 --tags' 'echo ${finalAttrs.version}'
32 '';
33
34 nativeBuildInputs = [
35 protobuf
36 qt5.qmake
37 qt5.wrapQtAppsHook
38 pkg-config
39 installShellFiles
40 ];
41
42 buildInputs = [
43 qt5.qtbase
44 qt5.qtmultimedia
45 libsForQt5.poppler
46 ghostscript
47 poppler-utils
48 exempi
49 ];
50
51 installPhase = ''
52 runHook preInstall
53
54 installBin equalx
55 installManPage equalx.1
56 install -Dm644 equalx.appdata.xml $out/share/metainfo/eqaulx.appdata.xml
57 install -Dm644 resources/equalx.ico $out/share/icons/hicolor/256x256/apps/equalx.ico
58 install -Dm644 resources/equalx.desktop $out/share/applications/equalx.desktop
59
60 runHook postInstall
61 '';
62
63 meta = {
64 description = "Graphical interface to latex and a bunch of conversion programs";
65 homepage = "https://equalx.sourceforge.io/";
66 mainProgram = "equalx";
67 downloadPage = "https://gitlab.com/q-quark/equalx";
68 license = lib.licenses.gpl3Plus;
69 maintainers = with lib.maintainers; [ doronbehar ];
70 };
71})