tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 stdenv,
3 lib,
4 fetchFromGitHub,
5 fetchpatch,
6 openssl,
7}:
8
9let
10 eMailSrc = fetchFromGitHub {
11 owner = "deanproxy";
12 repo = "eMail";
13 rev = "7d23c8f508a52bd8809e2af4290417829b6bb5ae";
14 sha256 = "1cxxzhm36civ6vjdgrk7mfmlzkih44kdii6l2xgy4r434s8rzcpn";
15 };
16
17 srcRoot = eMailSrc.name;
18
19 dlibSrc = fetchFromGitHub {
20 owner = "deanproxy";
21 repo = "dlib";
22 rev = "f62f29e918748b7cea476220f7492672be81c9de";
23 sha256 = "0h34cikch98sb7nsqjnb9wl384c8ndln3m6yb1172l4y89qjg9rr";
24 };
25
26in
27
28stdenv.mkDerivation {
29 pname = "email-git";
30 version = "unstable-2016-01-31";
31 src = eMailSrc;
32
33 patches = [
34 # Pul patch pending upstream inclusion for -fno-common toolchain support:
35 # https://github.com/deanproxy/eMail/pull/61
36 (fetchpatch {
37 name = "fno-common.patch";
38 url = "https://github.com/deanproxy/eMail/commit/c3c1e52132832be0e51daa6e0037d5bb79a17751.patch";
39 sha256 = "17ndrb65g0v4y521333h4244419s8nncm0yx2jwv12sf0dl6gy8i";
40 })
41 ];
42
43 # opt out of GCC 15's stricter C standards
44 # https://github.com/NixOS/nixpkgs/issues/475479
45 env.NIX_CFLAGS_COMPILE = toString [ "-std=gnu17" ];
46
47 buildInputs = [ openssl ];
48
49 unpackPhase = ''
50 unpackPhase;
51 cp -Rp ${dlibSrc}/* ${srcRoot}/dlib;
52 chmod -R +w ${srcRoot}/dlib;
53 '';
54
55 meta = {
56 description = "Command line SMTP client";
57 license = with lib.licenses; [ gpl2Plus ];
58 homepage = "https://deanproxy.com/code";
59 platforms = lib.platforms.unix;
60 mainProgram = "email";
61 };
62}