tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 makeWrapper,
6 gtk2,
7 libcddb,
8 intltool,
9 pkg-config,
10 cdparanoia,
11 mp3Support ? false,
12 lame,
13 oggSupport ? true,
14 vorbis-tools,
15 flacSupport ? true,
16 flac,
17 opusSupport ? false,
18 opusTools,
19 wavpackSupport ? false,
20 wavpack,
21 #, musepackSupport ? false, TODO: mpcenc
22 monkeysAudioSupport ? false,
23 monkeysAudio,
24 #, aacSupport ? false, TODO: neroAacEnc
25}:
26
27let
28 runtimeDeps =
29 lib.optional mp3Support lame
30 ++ lib.optional oggSupport vorbis-tools
31 ++ lib.optional flacSupport flac
32 ++ lib.optional opusSupport opusTools
33 ++ lib.optional wavpackSupport wavpack
34 ++ lib.optional monkeysAudioSupport monkeysAudio
35 ++ [ cdparanoia ];
36in
37
38stdenv.mkDerivation (finalAttrs: {
39 version = "3.0.1";
40 pname = "asunder";
41 src = fetchurl {
42 url = "http://littlesvr.ca/asunder/releases/asunder-${finalAttrs.version}.tar.bz2";
43 hash = "sha256-iGji4bl7ZofIAOf2EiYqMWu4V+3TmIN2jOYottJTN2s=";
44 };
45
46 nativeBuildInputs = [
47 intltool
48 makeWrapper
49 pkg-config
50 ];
51 buildInputs = [
52 gtk2
53 libcddb
54 ];
55
56 postInstall = ''
57 wrapProgram "$out/bin/asunder" \
58 --prefix PATH : "${lib.makeBinPath runtimeDeps}"
59 '';
60
61 meta = {
62 description = "Graphical Audio CD ripper and encoder for Linux";
63 mainProgram = "asunder";
64 homepage = "http://littlesvr.ca/asunder/index.php";
65 license = lib.licenses.gpl2;
66 maintainers = with lib.maintainers; [ mudri ];
67 platforms = lib.platforms.linux;
68
69 longDescription = ''
70 Asunder is a graphical Audio CD ripper and encoder for Linux. You can use
71 it to save tracks from an Audio CD as any of WAV, MP3, OGG, FLAC, Opus,
72 WavPack, Musepack, AAC, and Monkey's Audio files.
73 '';
74 };
75})