tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 stdenv,
3 lib,
4 fetchFromGitLab,
5 fetchpatch,
6 autoreconfHook,
7 pkg-config,
8 pcsclite,
9}:
10
11stdenv.mkDerivation {
12 pname = "aribb25";
13 # FIXME: change the rev for fetchFromGitLab in next release
14 version = "0.2.7";
15
16 src = fetchFromGitLab {
17 domain = "code.videolan.org";
18 owner = "videolan";
19 repo = "aribb25";
20 # tag = version; FIXME: uncomment in next release
21 rev = "c14938692b313b5ba953543fd94fd1cad0eeef18"; # 0.2.7 with build fixes
22 sha256 = "1kb9crfqib0npiyjk4zb63zqlzbhqm35nz8nafsvdjd71qbd2amp";
23 };
24
25 nativeBuildInputs = [
26 autoreconfHook
27 pkg-config
28 ];
29
30 buildInputs = lib.optionals stdenv.hostPlatform.isLinux [ pcsclite ];
31
32 env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-deprecated-non-prototype";
33
34 patches =
35 let
36 url = commit: "https://code.videolan.org/videolan/aribb25/-/commit/${commit}.diff";
37 in
38 [
39 (fetchpatch {
40 name = "make-cli-pipes-work-1.patch";
41 url = url "0425184dbf3fdaf59854af5f530da88b2196a57b";
42 sha256 = "0ysm2jivpnqxz71vw1102616qxww2gx005i0c5lhi6jbajqsa1cd";
43 })
44 (fetchpatch {
45 name = "make-cli-pipes-work-2.patch";
46 url = url "cebabeab2bda065dca1c9f033b42d391be866d86";
47 sha256 = "1283kqv1r4rbaba0sv2hphkhcxgjkmh8ndlcd24fhx43nn63hd28";
48 })
49 ];
50
51 meta = {
52 description = "Sample implementation of the ARIB STD-B25 standard";
53 homepage = "https://code.videolan.org/videolan/aribb25";
54 license = lib.licenses.isc;
55 maintainers = with lib.maintainers; [ midchildan ];
56 mainProgram = "b25";
57 platforms = lib.platforms.all;
58 };
59}