tjh.dev
1{ lib, stdenv, fetchFromGitHub
2, autoPatchelfHook
3, fuse3
4, maven, jdk, makeShellWrapper, glib, wrapGAppsHook
5}:
6
7let
8 pname = "cryptomator";
9 version = "1.8.0";
10
11 src = fetchFromGitHub {
12 owner = "cryptomator";
13 repo = "cryptomator";
14 rev = version;
15 sha256 = "sha256-4MjF2PDH0JB1biY4HO2wOC0i6EIGSlzkK6tDm8nzvIo=";
16 };
17
18 # perform fake build to make a fixed-output derivation out of the files downloaded from maven central (120MB)
19 deps = stdenv.mkDerivation {
20 name = "cryptomator-${version}-deps";
21 inherit src;
22
23 nativeBuildInputs = [ jdk maven ];
24 buildInputs = [ jdk ];
25
26 buildPhase = ''
27 while mvn -Plinux package -Dmaven.test.skip=true -Dmaven.repo.local=$out/.m2 -Dmaven.wagon.rto=5000; [ $? = 1 ]; do
28 echo "timeout, restart maven to continue downloading"
29 done
30 '';
31
32 # keep only *.{pom,jar,sha1,nbm} and delete all ephemeral files with lastModified timestamps inside
33 installPhase = ''
34 find $out/.m2 -type f -regex '.+\(\.lastUpdated\|resolver-status\.properties\|_remote\.repositories\)' -delete
35 find $out/.m2 -type f -iname '*.pom' -exec sed -i -e 's/\r\+$//' {} \;
36 '';
37
38 outputHashMode = "recursive";
39 outputHash = "sha256-2nCaSL7OlS9f+PZPh0YiMvnjOaAqlQimkKWDSjSP+bQ=";
40
41 doCheck = false;
42 };
43
44in stdenv.mkDerivation rec {
45 inherit pname version src;
46
47 buildPhase = ''
48 VERSION=${version}
49 SEMVER_STR=${version}
50
51 mvn -Plinux package --offline -Dmaven.test.skip=true -Dmaven.repo.local=$(cp -dpR ${deps}/.m2 ./ && chmod +w -R .m2 && pwd)/.m2
52 '';
53
54
55 # This is based on the instructins in https://github.com/cryptomator/cryptomator/blob/develop/dist/linux/appimage/build.sh
56 installPhase = ''
57 mkdir -p $out/bin/ $out/share/cryptomator/libs/ $out/share/cryptomator/mods/
58
59 cp target/libs/* $out/share/cryptomator/libs/
60 cp target/mods/* target/cryptomator-*.jar $out/share/cryptomator/mods/
61
62 makeShellWrapper ${jdk}/bin/java $out/bin/cryptomator \
63 --add-flags "--enable-preview" \
64 --add-flags "--class-path '$out/share/cryptomator/libs/*'" \
65 --add-flags "--module-path '$out/share/cryptomator/mods'" \
66 --add-flags "-Dcryptomator.logDir='~/.local/share/Cryptomator/logs'" \
67 --add-flags "-Dcryptomator.pluginDir='~/.local/share/Cryptomator/plugins'" \
68 --add-flags "-Dcryptomator.settingsPath='~/.config/Cryptomator/settings.json'" \
69 --add-flags "-Dcryptomator.ipcSocketPath='~/.config/Cryptomator/ipc.socket'" \
70 --add-flags "-Dcryptomator.mountPointsDir='~/.local/share/Cryptomator/mnt'" \
71 --add-flags "-Dcryptomator.showTrayIcon=false" \
72 --add-flags "-Dcryptomator.buildNumber='nix'" \
73 --add-flags "-Dcryptomator.appVersion='${version}'" \
74 --add-flags "-Djdk.gtk.version=3" \
75 --add-flags "-Xss20m" \
76 --add-flags "-Xmx512m" \
77 --add-flags "-Djavafx.embed.singleThread=true " \
78 --add-flags "-Dawt.useSystemAAFontSettings=on" \
79 --add-flags "--module org.cryptomator.desktop/org.cryptomator.launcher.Cryptomator" \
80 --prefix PATH : "$out/share/cryptomator/libs/:${lib.makeBinPath [ jdk glib ]}" \
81 --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ fuse3 ]}" \
82 --set JAVA_HOME "${jdk.home}"
83
84 # install desktop entry and icons
85 cp -r ${src}/dist/linux/appimage/resources/AppDir/usr/* $out/
86 # The directory is read only when copied, enable read to install additional files
87 chmod +w -R $out/
88 cp ${src}/dist/linux/common/org.cryptomator.Cryptomator256.png $out/share/icons/hicolor/256x256/apps/org.cryptomator.Cryptomator.png
89 cp ${src}/dist/linux/common/org.cryptomator.Cryptomator512.png $out/share/icons/hicolor/512x512/apps/org.cryptomator.Cryptomator.png
90 cp ${src}/dist/linux/common/org.cryptomator.Cryptomator.svg $out/share/icons/hicolor/scalable/apps/org.cryptomator.Cryptomator.svg
91 cp ${src}/dist/linux/common/org.cryptomator.Cryptomator.desktop $out/share/applications/org.cryptomator.Cryptomator.desktop
92 cp ${src}/dist/linux/common/org.cryptomator.Cryptomator.metainfo.xml $out/share/metainfo/org.cryptomator.Cryptomator.metainfo.xml
93 cp ${src}/dist/linux/common/application-vnd.cryptomator.vault.xml $out/share/mime/packages/application-vnd.cryptomator.vault.xml
94 '';
95
96 nativeBuildInputs = [
97 autoPatchelfHook
98 maven
99 makeShellWrapper
100 wrapGAppsHook
101 jdk
102 ];
103 buildInputs = [ fuse3 jdk glib ];
104
105 meta = with lib; {
106 description = "Free client-side encryption for your cloud files";
107 homepage = "https://cryptomator.org";
108 sourceProvenance = with sourceTypes; [
109 fromSource
110 binaryBytecode # deps
111 ];
112 license = licenses.gpl3Plus;
113 maintainers = with maintainers; [ bachp ];
114 platforms = [ "x86_64-linux" ];
115 };
116}