tjh.dev
1{ lib, stdenv, dpkg, fetchurl, zip, nixosTests }:
2
3let
4 generic = { version, sha256, suffix ? "", ... } @ args:
5 stdenv.mkDerivation (args // {
6 pname = "unifi-controller";
7
8 src = fetchurl {
9 url = "https://dl.ubnt.com/unifi/${version}${suffix}/unifi_sysvinit_all.deb";
10 inherit sha256;
11 };
12
13 nativeBuildInputs = [ dpkg ];
14
15 unpackPhase = ''
16 runHook preUnpack
17 dpkg-deb -x $src ./
18 runHook postUnpack
19 '';
20
21 installPhase = ''
22 runHook preInstall
23
24 mkdir -p $out
25 cd ./usr/lib/unifi
26 cp -ar dl lib webapps $out
27
28 runHook postInstall
29 '';
30
31 passthru.tests = {
32 unifi = nixosTests.unifi;
33 };
34
35 meta = with lib; {
36 homepage = "http://www.ubnt.com/";
37 description = "Controller for Ubiquiti UniFi access points";
38 sourceProvenance = with sourceTypes; [ binaryBytecode ];
39 license = licenses.unfree;
40 platforms = platforms.unix;
41 maintainers = with maintainers; [ globin patryk27 pennae ];
42 };
43 });
44
45in rec {
46 # see https://community.ui.com/releases / https://www.ui.com/download/unifi
47
48 unifiLTS = generic {
49 version = "5.6.42";
50 sha256 = "0wxkv774pw43c15jk0sg534l5za4j067nr85r5fw58iar3w2l84x";
51 };
52
53 unifi5 = generic {
54 version = "5.14.23";
55 sha256 = "1aar05yjm3z5a30x505w4kakbyz35i7mk7xyg0wm4ml6h94d84pv";
56
57 postInstall = ''
58 # Remove when log4j is updated to 2.12.2 or 2.16.0.
59 ${zip}/bin/zip -q -d $out/lib/log4j-core-*.jar org/apache/logging/log4j/core/lookup/JndiLookup.class
60 '';
61 };
62
63 unifi6 = generic {
64 version = "6.5.55";
65 sha256 = "sha256-NUGRO+f6JzWvYPwiitZsgp+LQwnGSncnost03mgNVxA=";
66 };
67
68 unifi7 = generic {
69 version = "7.3.83";
70 sha256 = "sha256-mDbF9vfoWjvABxcOIRngStji7xBllgZfUhVA9kF6ERU=";
71 };
72}