tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ stdenv, lib, fetchurl }:
2
3let
4
5 common = { versionMajor, versionMinor, sha256 }: stdenv.mkDerivation (rec {
6 pname = "apache-tomcat";
7 version = "${versionMajor}.${versionMinor}";
8
9 src = fetchurl {
10 url = "mirror://apache/tomcat/tomcat-${versionMajor}/v${version}/bin/${pname}-${version}.tar.gz";
11 inherit sha256;
12 };
13
14 outputs = [ "out" "webapps" ];
15 installPhase =
16 ''
17 mkdir $out
18 mv * $out
19 mkdir -p $webapps/webapps
20 mv $out/webapps $webapps/
21 '';
22
23 meta = with lib; {
24 homepage = "https://tomcat.apache.org/";
25 description = "An implementation of the Java Servlet and JavaServer Pages technologies";
26 platforms = platforms.all;
27 maintainers = [ ];
28 license = [ licenses.asl20 ];
29 sourceProvenance = with sourceTypes; [ binaryBytecode ];
30 };
31 });
32
33in {
34 tomcat9 = common {
35 versionMajor = "9";
36 versionMinor = "0.75";
37 sha256 = "sha256-VWfKg789z+ns1g3hDsCZFYQ+PsdqUEBeBHCihkGZelk=";
38 };
39
40 tomcat10 = common {
41 versionMajor = "10";
42 versionMinor = "0.27";
43 sha256 = "sha256-N2atmOdhVrGx88eXOc9Wziq8kn7IWzTeFyFpir/5HLc=";
44 };
45}