tjh.dev
1{ lib, callPackage, fetchFromGitHub, fetchurl, fetchpatch, stdenv, pkgsi686Linux }:
2
3let
4 generic = args: let
5 imported = import ./generic.nix args;
6 in callPackage imported {
7 lib32 = (pkgsi686Linux.callPackage imported {
8 libsOnly = true;
9 kernel = null;
10 }).out;
11 };
12
13 kernel = callPackage # a hacky way of extracting parameters from callPackage
14 ({ kernel, libsOnly ? false }: if libsOnly then { } else kernel) { };
15
16 selectHighestVersion = a: b: if lib.versionOlder a.version b.version
17 then b
18 else a;
19in
20rec {
21 # Official Unix Drivers - https://www.nvidia.com/en-us/drivers/unix/
22 # Branch/Maturity data - http://people.freedesktop.org/~aplattner/nvidia-versions.txt
23
24 # Policy: use the highest stable version as the default (on our master).
25 stable = if stdenv.hostPlatform.system == "i686-linux" then legacy_390 else latest;
26
27 production = generic {
28 version = "525.116.04";
29 sha256_64bit = "sha256-hhDsgkR8/3LLXxizZX7ppjSlFRZiuK2QHrgfTE+2F/4=";
30 sha256_aarch64 = "sha256-k7k22z5PYZdBVfuYXVcl9SFUMqZmK4qyxoRwlYyRdgU=";
31 openSha256 = "sha256-dktHCoESqoNfu5M73aY5MQGROlZawZwzBqs3RkOyfoQ=";
32 settingsSha256 = "sha256-qNjfsT9NGV151EHnG4fgBonVFSKc4yFEVomtXg9uYD4=";
33 persistencedSha256 = "sha256-ci86XGlno6DbHw6rkVSzBpopaapfJvk0+lHcR4LDq50=";
34
35 ibtSupport = true;
36 };
37
38 latest = selectHighestVersion production (generic {
39 version = "530.41.03";
40 sha256_64bit = "sha256-riehapaMhVA/XRYd2jQ8FgJhKwJfSu4V+S4uoKy3hLE=";
41 sha256_aarch64 = "sha256-uM5zMEO/AO32VmqUOzmc05FFm/lz76jPSSaQmeZUlFo=";
42 openSha256 = "sha256-etbtw6LMRUcFoZC9EDDRrTDekV8JFRYmkp3idLaMk5g=";
43 settingsSha256 = "sha256-8KB6T9f+gWl8Ni+uOyrJKiiH5mNx9eyfCcW/RjPTQQA=";
44 persistencedSha256 = "sha256-zrstlt/0YVGnsPGUuBbR9ULutywi2wNDVxh7OhJM7tM=";
45
46 patchFlags = [ "-p1" "-d" "kernel" ];
47 patches = [
48 # source: https://gist.github.com/joanbm/77f0650d45747b9a4dc8e330ade2bf5c
49 (fetchpatch {
50 url = "https://gist.github.com/joanbm/77f0650d45747b9a4dc8e330ade2bf5c/raw/688b612624945926676de28059fe749203b4b549/nvidia-470xx-fix-linux-6.4.patch";
51 hash = "sha256-OyRmezyzqAi7mSJHDjsWQVocSsgJPTW5DvHDFVNX7Dk=";
52 })
53 ];
54 });
55
56 beta = selectHighestVersion latest (generic {
57 version = "535.43.02";
58 sha256_64bit = "sha256-4KTdk4kGDmBGyHntMIzWRivUpEpzmra+p7RBsTL8mYM=";
59 sha256_aarch64 = "sha256-0blD8R+xpOVlitWefIbtw1d3KAnmWHBy7hkxGZHBrE4=";
60 openSha256 = "sha256-W1fwbbEEM7Z/S3J0djxGTtVTewbSALqX1G1OSpdajCM=";
61 settingsSha256 = "sha256-j0sSEbtF2fapv4GSthVTkmJga+ycmrGc1OnGpV6jEkc=";
62 persistencedSha256 = "sha256-M0ovNaJo8SZwLW4CQz9accNK79Z5JtTJ9kKwOzicRZ4=";
63 });
64
65 # Vulkan developer beta driver
66 # See here for more information: https://developer.nvidia.com/vulkan-driver
67 vulkan_beta = generic rec {
68 version = "525.47.26";
69 persistencedVersion = "525.116.04";
70 settingsVersion = "525.116.04";
71 sha256_64bit = "sha256-QfxEUTi71Pav1qzO0mObmKbsyg6FHTAyc7jkOj9D4lY=";
72 openSha256 = "sha256-QFpFRPpBXAB7v2+NP/M/1T1qKDqjdhigHkktnVyWw20=";
73 settingsSha256 = "sha256-qNjfsT9NGV151EHnG4fgBonVFSKc4yFEVomtXg9uYD4=";
74 persistencedSha256 = "sha256-ci86XGlno6DbHw6rkVSzBpopaapfJvk0+lHcR4LDq50=";
75 url = "https://developer.nvidia.com/downloads/vulkan-beta-${lib.concatStrings (lib.splitString "." version)}-linux";
76 };
77
78 # Update note:
79 # If you add a legacy driver here, also update `top-level/linux-kernels.nix`,
80 # adding to the `nvidia_x11_legacy*` entries.
81
82 # Last one supporting Kepler architecture
83 legacy_470 = generic {
84 version = "470.182.03";
85 sha256_64bit = "sha256-PbwUCPxIuGXT3azvxF9KP8E7kLg6Yo7lRrAIKrLD/Hk=";
86 sha256_aarch64 = "sha256-FEoWikgQjZKkHvAHgtkxnDhB41GdYplZTttEUBit4QQ=";
87 settingsSha256 = "sha256-TRKQ4brLnCbBZt1smGSIHTfwW+wEFPWWPEwDxjVXN7s=";
88 persistencedSha256 = "sha256-fSJMx49z9trdNxx0iPI45oG57smvvhaqVNxsRnfXKCI=";
89
90 patchFlags = [ "-p1" "-d" "kernel" ];
91 patches = [
92 # source: https://gist.github.com/joanbm/d10e9cbbbb8e245b6e7e27b2db338faf
93 (fetchpatch {
94 url = "https://gist.github.com/joanbm/d10e9cbbbb8e245b6e7e27b2db338faf/raw/f5d5238bdbaa16cd4008658a0f82b9dd84f1b38f/nvidia-470xx-fix-linux-6.3.patch";
95 hash = "sha256-mR+vXDHgVhWC0JeLgGlbNVCH8XTs7XnhEJS6BV75tI8=";
96 })
97 # source: https://gist.github.com/joanbm/77f0650d45747b9a4dc8e330ade2bf5c
98 (fetchpatch {
99 url = "https://gist.github.com/joanbm/77f0650d45747b9a4dc8e330ade2bf5c/raw/688b612624945926676de28059fe749203b4b549/nvidia-470xx-fix-linux-6.4.patch";
100 hash = "sha256-OyRmezyzqAi7mSJHDjsWQVocSsgJPTW5DvHDFVNX7Dk=";
101 })
102 ];
103 };
104
105 # Last one supporting x86
106 legacy_390 = generic {
107 version = "390.157";
108 sha256_32bit = "sha256-VdZeCkU5qct5YgDF8Qgv4mP7CVHeqvlqnP/rioD3B5k=";
109 sha256_64bit = "sha256-W+u8puj+1da52BBw+541HxjtxTSVJVPL3HHo/QubMoo=";
110 settingsSha256 = "sha256-uJZO4ak/w/yeTQ9QdXJSiaURDLkevlI81de0q4PpFpw=";
111 persistencedSha256 = "sha256-NuqUQbVt80gYTXgIcu0crAORfsj9BCRooyH3Gp1y1ns=";
112
113 broken = kernel.kernelAtLeast "6.2";
114 };
115
116 legacy_340 = let
117 # Source cooresponding to https://aur.archlinux.org/packages/nvidia-340xx-dkms
118 aurPatches = fetchFromGitHub {
119 owner = "archlinux-jerry";
120 repo = "nvidia-340xx";
121 rev = "f472f9297fe2ae285b954cd3f88abd8e2e255e4f";
122 hash = "sha256-tMA69Wlhi14DMS3O3nfwMX3EiT8pKa6McLxFpAayoEI=";
123 };
124 patchset = [
125 "0001-kernel-5.7.patch"
126 "0002-kernel-5.8.patch"
127 "0003-kernel-5.9.patch"
128 "0004-kernel-5.10.patch"
129 "0005-kernel-5.11.patch"
130 "0006-kernel-5.14.patch"
131 "0007-kernel-5.15.patch"
132 "0008-kernel-5.16.patch"
133 "0009-kernel-5.17.patch"
134 "0010-kernel-5.18.patch"
135 "0011-kernel-6.0.patch"
136 "0012-kernel-6.2.patch"
137 "0013-kernel-6.3.patch"
138 ];
139 in generic {
140 version = "340.108";
141 sha256_32bit = "1jkwa1phf0x4sgw8pvr9d6krmmr3wkgwyygrxhdazwyr2bbalci0";
142 sha256_64bit = "06xp6c0sa7v1b82gf0pq0i5p0vdhmm3v964v0ypw36y0nzqx8wf6";
143 settingsSha256 = "0zm29jcf0mp1nykcravnzb5isypm8l8mg2gpsvwxipb7nk1ivy34";
144 persistencedSha256 = "1ax4xn3nmxg1y6immq933cqzw6cj04x93saiasdc0kjlv0pvvnkn";
145 useGLVND = false;
146
147 broken = kernel.kernelAtLeast "6.4";
148 patches = map (patch: "${aurPatches}/${patch}") patchset;
149 };
150}