tjh.dev
1{ lib, stdenv, fetchgit
2, bison, flex, rasdaemon
3}:
4
5{
6 edac-inject = rasdaemon.inject;
7
8 mce-inject = stdenv.mkDerivation rec {
9 pname = "mce-inject";
10 version = "4cbe46321b4a81365ff3aafafe63967264dbfec5";
11
12 src = fetchgit {
13 url = "https://git.kernel.org/pub/scm/utils/cpu/mce/mce-inject.git";
14 rev = version;
15 sha256 = "0gjapg2hrlxp8ssrnhvc19i3r1xpcnql7xv0zjgbv09zyha08g6z";
16 };
17
18 nativeBuildInputs = [ bison flex ];
19
20 makeFlags = [ "destdir=${placeholder "out"}" ];
21
22 postInstall = ''
23 mkdir $out/sbin
24 mv $out/usr/sbin/mce-inject $out/sbin/mce-inject
25
26 mkdir $out/test
27 cp test/* $out/test/.
28 '';
29
30 meta = with lib; {
31 description = "MCE error injection tool";
32 license = licenses.gpl2Only;
33 platforms = platforms.linux;
34 maintainers = [ maintainers.evils ];
35 };
36 };
37
38 aer-inject = stdenv.mkDerivation rec {
39 pname = "aer-inject";
40 version = "9bd5e2c7886fca72f139cd8402488a2235957d41";
41
42 src = fetchgit {
43 url = "https://git.kernel.org/pub/scm/linux/kernel/git/gong.chen/aer-inject.git";
44 rev = version;
45 sha256 = "0bh6mzpk2mr4xidkammmkfk21b4dbq793qjg25ryyxd1qv0c6cg4";
46 };
47
48 nativeBuildInputs = [ bison flex ];
49
50 # how is this necessary?
51 makeFlags = [ "DESTDIR=${placeholder "out"}" ];
52
53 postInstall = ''
54 mkdir $out/bin
55 mv $out/usr/local/aer-inject $out/bin/aer-inject
56
57 mkdir -p $out/examples
58 cp examples/* $out/examples/.
59 '';
60
61 meta = with lib; {
62 description = "PCIE AER error injection tool";
63 license = licenses.gpl2Only;
64 platforms = platforms.linux;
65 maintainers = [ maintainers.evils ];
66 };
67 };
68}