tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, fetchurl, cmake, pkg-config
2, SDL2, libvorbis, libogg, libjpeg, libpng, freetype, glew, tinyxml, openal
3, freealut, readline, gcc-unwrapped
4, enableSoundtrack ? false # Enable the "Open Clonk Soundtrack - Explorers Journey" by David Oerther
5}:
6
7let
8 soundtrack_src = fetchurl {
9 url = "http://www.openclonk.org/download/Music.ocg";
10 sha256 = "1ckj0dlpp5zsnkbb5qxxfxpkiq76jj2fgj91fyf3ll7n0gbwcgw5";
11 };
12in stdenv.mkDerivation rec {
13 version = "8.1";
14 pname = "openclonk";
15
16 src = fetchurl {
17 url = "https://www.openclonk.org/builds/release/8.1/openclonk-${version}-src.tar.bz2";
18 sha256 = "0imkqjp8lww5p0cnqf4k4mb2v682mnsas63qmiz17rspakr7fxik";
19 };
20
21 postInstall = ''
22 mv -v $out/games/openclonk $out/bin/
23 '' + lib.optionalString enableSoundtrack ''
24 ln -sv ${soundtrack_src} $out/share/games/openclonk/Music.ocg
25 '';
26
27 nativeBuildInputs = [ cmake pkg-config ];
28
29 buildInputs = [
30 SDL2 libvorbis libogg libjpeg libpng freetype glew tinyxml openal freealut
31 readline
32 ];
33
34 cmakeFlags = [ "-DCMAKE_AR=${gcc-unwrapped}/bin/gcc-ar" "-DCMAKE_RANLIB=${gcc-unwrapped}/bin/gcc-ranlib" ];
35
36 cmakeBuildType = "RelWithDebInfo";
37
38 meta = with lib; {
39 description = "Free multiplayer action game in which you control clonks, small but witty and nimble humanoid beings";
40 homepage = "https://www.openclonk.org";
41 license = if enableSoundtrack then licenses.unfreeRedistributable else licenses.isc;
42 maintainers = with maintainers; [ lheckemann ];
43 platforms = [ "x86_64-linux" "i686-linux" ];
44 broken = true;
45 };
46}