tjh.dev
1{ lib, stdenv, fetchFromGitHub, SDL2, cmake, makeWrapper }:
2
3stdenv.mkDerivation rec {
4 pname = "nanosaur";
5 version = "unstable-2021-12-03";
6
7 src = fetchFromGitHub {
8 owner = "jorio";
9 repo = pname;
10 rev = "b567a3e6d7fd1cbc43800cfaa1bd82f31c6d9fae";
11 sha256 = "sha256-P/o6uSwUV6O8u8XNXN9YyA8XlgEUkqGj3SC+oD2/GKQ=";
12 fetchSubmodules = true;
13 };
14
15 nativeBuildInputs = [
16 cmake
17 makeWrapper
18 ];
19 buildInputs = [
20 SDL2
21 ];
22
23 cmakeFlags = [ "-DCMAKE_BUILD_TYPE=Release" ];
24
25 installPhase = ''
26 runHook preInstall
27 mkdir -p "$out/bin"
28 mkdir -p "$out/share/Nanosaur"
29 mv Data ReadMe.txt "$out/share/Nanosaur/"
30 install -Dm755 {.,$out/bin}/Nanosaur
31 wrapProgram $out/bin/Nanosaur --chdir "$out/share/Nanosaur"
32 install -Dm644 $src/packaging/nanosaur.desktop $out/share/applications/nanosaur.desktop
33 install -Dm644 $src/packaging/nanosaur-desktopicon.png $out/share/pixmaps/nanosaur-desktopicon.png
34 runHook postInstall
35 '';
36
37 meta = with lib; {
38 description = "A port of Nanosaur, a 1998 Macintosh game by Pangea Software, for modern operating systems";
39 longDescription = ''
40 Nanosaur is a 1998 Macintosh game by Pangea Software.
41 In it, you’re a cybernetic dinosaur from the future who’s sent back in time 20 minutes before a giant asteroid hits the Earth.
42 And you get to shoot at T-Rexes with nukes.
43 '';
44 homepage = "https://github.com/jorio/Nanosaur";
45 license = licenses.cc-by-sa-40;
46 maintainers = with maintainers; [ lux ];
47 platforms = platforms.linux;
48 };
49}