tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{ lib
2, stdenv
3, python3
4, fetchFromGitHub
5, makeWrapper
6, gdb
7}:
8
9let
10 pythonPath = with python3.pkgs; makePythonPath [
11 capstone
12 future
13 psutil
14 pwntools
15 pycparser
16 pyelftools
17 pygments
18 unicorn
19 rpyc
20 ];
21 binPath = lib.makeBinPath ([
22 python3.pkgs.pwntools # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/wrappers/checksec.py#L8
23 ] ++ lib.optionals stdenv.isLinux [
24 python3.pkgs.ropper # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/ropper.py#L30
25 python3.pkgs.ropgadget # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/rop.py#L32
26 ]);
27
28in stdenv.mkDerivation rec {
29 pname = "pwndbg";
30 version = "2022.12.19";
31 format = "other";
32
33 src = fetchFromGitHub {
34 owner = "pwndbg";
35 repo = "pwndbg";
36 rev = version;
37 sha256 = "sha256-pyY2bMasd6GaJZZjLF48SvkKUBw3XfVa0g3Q0LiEi4k=";
38 fetchSubmodules = true;
39 };
40
41 nativeBuildInputs = [ makeWrapper ];
42
43 installPhase = ''
44 mkdir -p $out/share/pwndbg
45 cp -r *.py pwndbg gdb-pt-dump $out/share/pwndbg
46 chmod +x $out/share/pwndbg/gdbinit.py
47 makeWrapper ${gdb}/bin/gdb $out/bin/pwndbg \
48 --add-flags "-q -x $out/share/pwndbg/gdbinit.py" \
49 --prefix PATH : ${binPath} \
50 --set NIX_PYTHONPATH ${pythonPath}
51 '';
52
53 meta = with lib; {
54 description = "Exploit Development and Reverse Engineering with GDB Made Easy";
55 homepage = "https://github.com/pwndbg/pwndbg";
56 license = licenses.mit;
57 platforms = platforms.all;
58 maintainers = with maintainers; [ mic92 patryk4815 ];
59 # not supported on aarch64-darwin see: https://inbox.sourceware.org/gdb/3185c3b8-8a91-4beb-a5d5-9db6afb93713@Spark/
60 broken = stdenv.isDarwin && stdenv.isAarch64;
61 };
62}