tjh.dev
1{ lib, stdenv, fetchFromGitHub, ninja, makeWrapper, CoreFoundation, Foundation }:
2
3stdenv.mkDerivation rec {
4 pname = "lua-language-server";
5 version = "3.6.21";
6
7 src = fetchFromGitHub {
8 owner = "luals";
9 repo = "lua-language-server";
10 rev = version;
11 sha256 = "sha256-db3lNo6aJXU0WaUXlegEK87kuXQUVBrTAFtvCeb7PzY=";
12 fetchSubmodules = true;
13 };
14
15 nativeBuildInputs = [
16 ninja
17 makeWrapper
18 ];
19
20 buildInputs = lib.optionals stdenv.isDarwin [
21 CoreFoundation
22 Foundation
23 ];
24
25 postPatch = ''
26 # filewatch tests are failing on darwin
27 # this feature is not used in lua-language-server
28 sed -i /filewatch/d 3rd/bee.lua/test/test.lua
29
30 pushd 3rd/luamake
31 '' + lib.optionalString stdenv.isDarwin ''
32 # This package uses the program clang for C and C++ files. The language
33 # is selected via the command line argument -std, but this do not work
34 # in combination with the nixpkgs clang wrapper. Therefor we have to
35 # find all c++ compiler statements and replace $cc (which expands to
36 # clang) with clang++.
37 sed -i compile/ninja/macos.ninja \
38 -e '/c++/s,$cc,clang++,' \
39 -e '/test.lua/s,= .*,= true,' \
40 -e '/ldl/s,$cc,clang++,'
41 sed -i scripts/compiler/gcc.lua \
42 -e '/cxx_/s,$cc,clang++,'
43 '';
44
45 ninjaFlags = [
46 "-fcompile/ninja/${if stdenv.isDarwin then "macos" else "linux"}.ninja"
47 ];
48
49 postBuild = ''
50 popd
51 ./3rd/luamake/luamake rebuild
52 '';
53
54 installPhase = ''
55 runHook preInstall
56
57 install -Dt "$out"/share/lua-language-server/bin bin/lua-language-server
58 install -m644 -t "$out"/share/lua-language-server/bin bin/*.*
59 install -m644 -t "$out"/share/lua-language-server {debugger,main}.lua
60 cp -r locale meta script "$out"/share/lua-language-server
61
62 # necessary for --version to work:
63 install -m644 -t "$out"/share/lua-language-server changelog.md
64
65 makeWrapper "$out"/share/lua-language-server/bin/lua-language-server \
66 $out/bin/lua-language-server \
67 --add-flags "-E $out/share/lua-language-server/main.lua \
68 --logpath=\''${XDG_CACHE_HOME:-\$HOME/.cache}/lua-language-server/log \
69 --metapath=\''${XDG_CACHE_HOME:-\$HOME/.cache}/lua-language-server/meta"
70
71 runHook postInstall
72 '';
73
74 # some tests require local networking
75 __darwinAllowLocalNetworking = true;
76
77 meta = with lib; {
78 description = "A language server that offers Lua language support";
79 homepage = "https://github.com/luals/lua-language-server";
80 changelog = "https://github.com/LuaLS/lua-language-server/blob/${version}/changelog.md";
81 license = licenses.mit;
82 maintainers = with maintainers; [ figsoda sei40kr ];
83 platforms = platforms.linux ++ platforms.darwin;
84 };
85}