tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{ lib
2, buildDunePackage, camlp5
3, ocaml
4, menhir, menhirLib
5, atdgen
6, stdlib-shims
7, re, perl, ncurses
8, ppxlib, ppx_deriving
9, ppxlib_0_15, ppx_deriving_0_15
10, coqPackages
11, version ? if lib.versionAtLeast ocaml.version "4.08" then "1.16.5"
12 else if lib.versionAtLeast ocaml.version "4.07" then "1.15.2" else "1.14.1"
13}:
14
15let fetched = coqPackages.metaFetch ({
16 release."1.16.5".sha256 = "sha256-tKX5/cVPoBeHiUe+qn7c5FIRYCwY0AAukN7vSd/Nz9A=";
17 release."1.15.2".sha256 = "sha256-XgopNP83POFbMNyl2D+gY1rmqGg03o++Ngv3zJfCn2s=";
18 release."1.15.0".sha256 = "sha256:1ngdc41sgyzyz3i3lkzjhnj66gza5h912virkh077dyv17ysb6ar";
19 release."1.14.1".sha256 = "sha256-BZPVL8ymjrE9kVGyf6bpc+GA2spS5JBpkUtZi04nPis=";
20 release."1.13.7".sha256 = "10fnwz30bsvj7ii1vg4l1li5pd7n0qqmwj18snkdr5j9gk0apc1r";
21 release."1.13.5".sha256 = "02a6r23mximrdvs6kgv6rp0r2dgk7zynbs99nn7lphw2c4189kka";
22 release."1.13.1".sha256 = "12a9nbdvg9gybpw63lx3nw5wnxfznpraprb0wj3l68v1w43xq044";
23 release."1.13.0".sha256 = "0dmzy058m1mkndv90byjaik6lzzfk3aaac7v84mpmkv6my23bygr";
24 release."1.12.0".sha256 = "1agisdnaq9wrw3r73xz14yrq3wx742i6j8i5icjagqk0ypmly2is";
25 release."1.11.4".sha256 = "1m0jk9swcs3jcrw5yyw5343v8mgax238cjb03s8gc4wipw1fn9f5";
26 releaseRev = v: "v${v}";
27 location = { domain = "github.com"; owner = "LPCIC"; repo = "elpi"; };
28 }) version;
29in
30buildDunePackage rec {
31 pname = "elpi";
32 inherit (fetched) version src;
33
34 patches = lib.optional (lib.versionAtLeast version "1.16" || version == "dev")
35 ./atd_2_10.patch;
36
37 minimalOCamlVersion = "4.04";
38 duneVersion = "3";
39
40 # atdgen is both a library and executable
41 nativeBuildInputs = [ perl ]
42 ++ [ (if lib.versionAtLeast version "1.15" || version == "dev" then menhir else camlp5) ]
43 ++ lib.optional (lib.versionAtLeast version "1.16" || version == "dev") atdgen;
44 buildInputs = [ ncurses ]
45 ++ lib.optional (lib.versionAtLeast version "1.16" || version == "dev") atdgen;
46
47 propagatedBuildInputs = [ re stdlib-shims ]
48 ++ (if lib.versionAtLeast version "1.15" || version == "dev"
49 then [ menhirLib ]
50 else [ camlp5 ]
51 )
52 ++ (if lib.versionAtLeast version "1.13" || version == "dev"
53 then [ ppxlib ppx_deriving ]
54 else [ ppxlib_0_15 ppx_deriving_0_15 ]
55 );
56
57 meta = with lib; {
58 description = "Embeddable λProlog Interpreter";
59 license = licenses.lgpl21Plus;
60 maintainers = [ maintainers.vbgl ];
61 homepage = "https://github.com/LPCIC/elpi";
62 };
63
64 postPatch = ''
65 substituteInPlace elpi_REPL.ml --replace "tput cols" "${ncurses}/bin/tput cols"
66 '';
67}