tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{ lib, stdenv, fetchFromGitHub, cmake, boost, pkg-config, doxygen, qt48Full, libharu
2, pango, fcgi, firebird, libmysqlclient, postgresql, graphicsmagick, glew, openssl
3, pcre, harfbuzz, icu
4}:
5
6let
7 generic =
8 { version, sha256 }:
9 stdenv.mkDerivation {
10 pname = "wt";
11 inherit version;
12
13 src = fetchFromGitHub {
14 owner = "emweb";
15 repo = "wt";
16 rev = version;
17 inherit sha256;
18 };
19
20 nativeBuildInputs = [ cmake pkg-config ];
21 buildInputs = [
22 boost doxygen qt48Full libharu
23 pango fcgi firebird libmysqlclient postgresql graphicsmagick glew
24 openssl pcre harfbuzz icu
25 ];
26
27 cmakeFlags = [
28 "-DWT_CPP_11_MODE=-std=c++11"
29 "--no-warn-unused-cli"
30 ]
31 ++ lib.optionals (graphicsmagick != null) [
32 "-DWT_WRASTERIMAGE_IMPLEMENTATION=GraphicsMagick"
33 "-DGM_PREFIX=${graphicsmagick}"
34 ]
35 ++ lib.optional (libmysqlclient != null)
36 "-DMYSQL_PREFIX=${libmysqlclient}";
37
38 meta = with lib; {
39 homepage = "https://www.webtoolkit.eu/wt";
40 description = "C++ library for developing web applications";
41 platforms = platforms.linux;
42 license = licenses.gpl2;
43 maintainers = with maintainers; [ juliendehos willibutz ];
44 };
45 };
46in {
47 wt3 = generic {
48 version = "3.7.1";
49 sha256 = "19gf5lbrc5shpvcdyzjh20k8zdj4cybxqvkhwqfl9rvhw89qr11k";
50 };
51
52 wt4 = generic {
53 version = "4.9.1";
54 sha256 = "sha256-Qm0qqYB/CLVHUgKE9N83MgAWQ2YFdumrB0i84qYNto8=";
55 };
56}