tjh.dev
1{ stdenv, lib, fetchurl, meson, ninja, pkg-config
2, gtk-doc, docbook-xsl-nons
3, glib, ncurses, libxml2
4, buildDocs ? true
5}:
6stdenv.mkDerivation rec {
7 pname = "libgnt";
8 version = "2.14.1";
9
10 outputs = [ "out" "dev" ] ++ lib.optional buildDocs "devdoc";
11
12 src = fetchurl {
13 url = "mirror://sourceforge/pidgin/${pname}-${version}.tar.xz";
14 sha256 = "1n2bxg0ignn53c08cp69pj4sdg53kwlqn23rincyjmpr327fdhsy";
15 };
16
17 nativeBuildInputs = [ meson ninja pkg-config ]
18 ++ lib.optionals buildDocs [ gtk-doc docbook-xsl-nons ];
19
20 buildInputs = [ glib ncurses libxml2 ];
21
22 postPatch = ''
23 substituteInPlace meson.build --replace \
24 "ncurses_sys_prefix = '/usr'" \
25 "ncurses_sys_prefix = '${lib.getDev ncurses}'"
26 '' + lib.optionalString (!buildDocs) ''
27 sed "/^subdir('doc')$/d" -i meson.build
28 '';
29
30 meta = with lib; {
31 description = "An ncurses toolkit for creating text-mode graphical user interfaces";
32 homepage = "https://keep.imfreedom.org/libgnt/libgnt/";
33 license = licenses.gpl2Plus;
34 platforms = platforms.unix;
35 maintainers = with lib.maintainers; [ ony ];
36 };
37}