tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, fetchurl, pkg-config, glib, zlib, gnupg, libgpg-error, gobject-introspection }:
2
3stdenv.mkDerivation rec {
4 version = "2.6.23";
5 pname = "gmime";
6
7 src = fetchurl {
8 url = "mirror://gnome/sources/gmime/2.6/${pname}-${version}.tar.xz";
9 sha256 = "0slzlzcr3h8jikpz5a5amqd0csqh2m40gdk910ws2hnaf5m6hjbi";
10 };
11
12 outputs = [ "out" "dev" ];
13
14 nativeBuildInputs = [ pkg-config gobject-introspection ];
15 propagatedBuildInputs = [ glib zlib libgpg-error ];
16 configureFlags = [
17 "--enable-introspection=yes"
18 ] ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [ "ac_cv_have_iconv_detect_h=yes" ];
19
20 postPatch = ''
21 substituteInPlace tests/testsuite.c \
22 --replace /bin/rm rm \
23 --replace /bin/mkdir mkdir
24
25 substituteInPlace tests/test-pkcs7.c \
26 --replace /bin/mkdir mkdir
27 '';
28
29 preConfigure = lib.optionalString (stdenv.buildPlatform != stdenv.hostPlatform) ''
30 cp ${if stdenv.hostPlatform.isMusl then ./musl-iconv-detect.h else ./iconv-detect.h} ./iconv-detect.h
31 '';
32
33 nativeCheckInputs = [ gnupg ];
34
35 enableParallelBuilding = true;
36
37 meta = with lib; {
38 homepage = "https://github.com/jstedfast/gmime/";
39 description = "A C/C++ library for creating, editing and parsing MIME messages and structures";
40 license = licenses.lgpl21Plus;
41 maintainers = with maintainers; [ ];
42 platforms = platforms.unix;
43 };
44}