tjh.dev
1{ lib, stdenv, config, fetchurl, fetchpatch, pkg-config, audiofile, libcap, libiconv
2, libGLSupported ? lib.elem stdenv.hostPlatform.system lib.platforms.mesaPlatforms
3, openglSupport ? libGLSupported, libGL, libGLU
4, alsaSupport ? stdenv.isLinux && !stdenv.hostPlatform.isAndroid, alsa-lib
5, x11Support ? !stdenv.isCygwin && !stdenv.hostPlatform.isAndroid
6, libXext, libICE, libXrandr
7, pulseaudioSupport ? config.pulseaudio or stdenv.isLinux && !stdenv.hostPlatform.isAndroid, libpulseaudio
8, OpenGL, GLUT, CoreAudio, CoreServices, AudioUnit, Kernel, Cocoa
9}:
10
11# NOTE: When editing this expression see if the same change applies to
12# SDL2 expression too
13
14let
15 extraPropagatedBuildInputs = [ ]
16 ++ lib.optionals x11Support [ libXext libICE libXrandr ]
17 ++ lib.optionals (openglSupport && stdenv.isLinux) [ libGL libGLU ]
18 ++ lib.optionals (openglSupport && stdenv.isDarwin) [ OpenGL GLUT ]
19 ++ lib.optional alsaSupport alsa-lib
20 ++ lib.optional pulseaudioSupport libpulseaudio
21 ++ lib.optional stdenv.isDarwin Cocoa;
22 rpath = lib.makeLibraryPath extraPropagatedBuildInputs;
23in
24
25stdenv.mkDerivation rec {
26 pname = "SDL";
27 version = "1.2.15";
28
29 src = fetchurl {
30 url = "https://www.libsdl.org/release/${pname}-${version}.tar.gz";
31 sha256 = "005d993xcac8236fpvd1iawkz4wqjybkpn8dbwaliqz5jfkidlyn";
32 };
33
34 # make: *** No rule to make target 'build/*.lo', needed by 'build/libSDL.la'. Stop.
35 postPatch = "patchShebangs ./configure";
36
37 outputs = [ "out" "dev" ];
38 outputBin = "dev"; # sdl-config
39
40 nativeBuildInputs = [ pkg-config ]
41 ++ lib.optional stdenv.isLinux libcap;
42
43 propagatedBuildInputs = [ libiconv ] ++ extraPropagatedBuildInputs;
44
45 buildInputs = [ ]
46 ++ lib.optional (!stdenv.hostPlatform.isMinGW && alsaSupport) audiofile
47 ++ lib.optionals stdenv.isDarwin [ AudioUnit CoreAudio CoreServices Kernel OpenGL ];
48
49 configureFlags = [
50 "--disable-oss"
51 "--disable-video-x11-xme"
52 "--enable-rpath"
53 # Building without this fails on Darwin with
54 #
55 # ./src/video/x11/SDL_x11sym.h:168:17: error: conflicting types for '_XData32'
56 # SDL_X11_SYM(int,_XData32,(Display *dpy,register long *data,unsigned len),(dpy,data,len),return)
57 #
58 # Please try revert the change that introduced this comment when updating SDL.
59 ] ++ lib.optional stdenv.isDarwin "--disable-x11-shared"
60 ++ lib.optional (!x11Support) "--without-x"
61 ++ lib.optional alsaSupport "--with-alsa-prefix=${alsa-lib.out}/lib";
62
63 patches = [
64 ./find-headers.patch
65
66 # Fix window resizing issues, e.g. for xmonad
67 # Ticket: http://bugzilla.libsdl.org/show_bug.cgi?id=1430
68 (fetchpatch {
69 name = "fix_window_resizing.diff";
70 url = "https://bugs.debian.org/cgi-bin/bugreport.cgi?msg=10;filename=fix_window_resizing.diff;att=2;bug=665779";
71 sha256 = "1z35azc73vvi19pzi6byck31132a8w1vzrghp1x3hy4a4f9z4gc6";
72 })
73 # Fix drops of keyboard events for SDL_EnableUNICODE
74 (fetchpatch {
75 url = "https://github.com/libsdl-org/SDL-1.2/commit/0332e2bb18dc68d6892c3b653b2547afe323854b.patch";
76 sha256 = "0g458iv6pp9sikdch6ms8svz60lf5ks2q5wgid8s9rydhk98lpp5";
77 })
78 # Ignore insane joystick axis events
79 (fetchpatch {
80 url = "https://github.com/libsdl-org/SDL-1.2/commit/ab99cc82b0a898ad528d46fa128b649a220a94f4.patch";
81 sha256 = "1b3473sawfdbkkxaqf1hg0vn37yk8hf655jhnjwdk296z4gclazh";
82 })
83 # https://bugzilla.libsdl.org/show_bug.cgi?id=1769
84 (fetchpatch {
85 url = "https://github.com/libsdl-org/SDL-1.2/commit/5d79977ec7a6b58afa6e4817035aaaba186f7e9f.patch";
86 sha256 = "1k7y57b1zy5afib1g7w3in36n8cswbcrzdbrjpn5cb105rnb9vmp";
87 })
88 # Workaround X11 bug to allow changing gamma
89 # Ticket: https://bugs.freedesktop.org/show_bug.cgi?id=27222
90 (fetchpatch {
91 name = "SDL_SetGamma.patch";
92 url = "https://src.fedoraproject.org/rpms/SDL/raw/7a07323e5cec08bea6f390526f86a1ce5341596d/f/SDL-1.2.15-x11-Bypass-SetGammaRamp-when-changing-gamma.patch";
93 sha256 = "0x52s4328kilyq43i7psqkqg7chsfwh0aawr50j566nzd7j51dlv";
94 })
95 # Fix a build failure on OS X Mavericks
96 # Ticket: https://bugzilla.libsdl.org/show_bug.cgi?id=2085
97 (fetchpatch {
98 url = "https://github.com/libsdl-org/SDL-1.2/commit/19039324be71738d8990e91b9ba341b2ea068445.patch";
99 sha256 = "0ckwling2ad27c9vxgp97ndjd098d6zbrydza8b9l77k8airj98c";
100 })
101 (fetchpatch {
102 url = "https://github.com/libsdl-org/SDL-1.2/commit/7933032ad4d57c24f2230db29f67eb7d21bb5654.patch";
103 sha256 = "1by16firaxyr0hjvn35whsgcmq6bl0nwhnpjf75grjzsw9qvwyia";
104 })
105 (fetchpatch {
106 name = "CVE-2022-34568.patch";
107 url = "https://github.com/libsdl-org/SDL-1.2/commit/d7e00208738a0bc6af302723fe64908ac35b777b.patch";
108 sha256 = "sha256-fuxXsqZW94/C8CKu9LakppCU4zHupj66O2MngQ4BO9o=";
109 })
110 ];
111
112 postInstall = ''
113 moveToOutput share/aclocal "$dev"
114 '';
115
116 # See the same place in the expression for SDL2
117 postFixup = ''
118 for lib in $out/lib/*.so* ; do
119 if [[ -L "$lib" ]]; then
120 patchelf --set-rpath "$(patchelf --print-rpath $lib):${rpath}" "$lib"
121 fi
122 done
123 '';
124
125 setupHook = ./setup-hook.sh;
126
127 passthru = { inherit openglSupport; };
128
129 enableParallelBuilding = true;
130
131 meta = with lib; {
132 description = "A cross-platform multimedia library";
133 homepage = "http://www.libsdl.org/";
134 maintainers = with maintainers; [ lovek323 ];
135 platforms = platforms.unix;
136 license = licenses.lgpl21;
137 };
138}