tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1{ lib, stdenv, fetchurl, unzip, libX11, libXt, libnsl, libxcrypt }:
2
3stdenv.mkDerivation {
4 pname = "unicon-lang";
5 version = "11.7";
6 src = fetchurl {
7 url = "http://unicon.org/dist/uni-2-4-2010.zip";
8 sha256 = "1g9l2dfp99dqih2ir2limqfjgagh3v9aqly6x0l3qavx3qkkwf61";
9 };
10 nativeBuildInputs = [ unzip ];
11 buildInputs = [ libnsl libX11 libXt libxcrypt ];
12
13 hardeningDisable = [ "fortify" ];
14
15 sourceRoot = ".";
16
17 # Workaround build failure on -fno-common toolchains like upstream
18 # gcc-10. Otherwise build fails as:
19 # ld: ../common/ipp.o:(.bss+0x0): multiple definition of `lpath'; tglobals.o:(.bss+0x30): first defined here
20 # TODO: remove the workaround once upstream releases version past:
21 # https://sourceforge.net/p/unicon/unicon/ci/b1a65230233f3825d055aee913b4fdcf178a0eaf/
22 env.NIX_CFLAGS_COMPILE = "-fcommon";
23
24 configurePhase = ''
25 case "$(uname -a | sed 's/ /_/g')" in
26 Darwin*Version_9*i386) sys=intel_macos;;
27 Linux*x86_64*) sys=amd64_linux;;
28 Linux*i686*) sys=intel_linux;;
29 *) sys=unknown;;
30 esac
31 echo "all: ; echo" > uni/3d/makefile
32 make X-Configure name=$sys
33 '';
34
35 buildPhase = ''
36 make Unicon
37 '';
38
39 installPhase = ''
40 mkdir -p $out/
41 cp -r bin $out/
42 '';
43
44 meta = with lib; {
45 broken = (stdenv.isLinux && stdenv.isAarch64);
46 description = "A very high level, goal-directed, object-oriented, general purpose applications language";
47 maintainers = with maintainers; [ vrthra ];
48 platforms = platforms.linux;
49 license = licenses.gpl2;
50 homepage = "http://unicon.org";
51 };
52}