tjh.dev
1{ pkgs, haskellLib }:
2
3with haskellLib;
4
5self: super:
6let
7 # This contains updates to the dependencies, without which it would
8 # be even more work to get it to build.
9 # As of 2020-04, there's no new release in sight, which is why we're
10 # pulling from Github.
11 tensorflow-haskell = pkgs.fetchFromGitHub {
12 owner = "tensorflow";
13 repo = "haskell";
14 rev = "555d90c43202d5a3021893013bfc8e2ffff58c97";
15 sha256 = "uOuIeD4o+pcjvluTqyVU3GJUQ4e1+p3FhINJ9b6oK+k=";
16 fetchSubmodules = true;
17 };
18
19 setTensorflowSourceRoot = dir: drv:
20 (overrideCabal (drv: { src = tensorflow-haskell; }) drv)
21 .overrideAttrs (_oldAttrs: {sourceRoot = "source/${dir}";});
22in
23{
24 tensorflow-proto = doJailbreak (setTensorflowSourceRoot "tensorflow-proto" super.tensorflow-proto);
25
26 tensorflow = overrideCabal
27 (drv: { libraryHaskellDepends = drv.libraryHaskellDepends ++ [self.vector-split]; })
28 (setTensorflowSourceRoot "tensorflow" super.tensorflow);
29
30 tensorflow-core-ops = setTensorflowSourceRoot "tensorflow-core-ops" super.tensorflow-core-ops;
31
32 tensorflow-logging = setTensorflowSourceRoot "tensorflow-logging" super.tensorflow-logging;
33
34 tensorflow-opgen = setTensorflowSourceRoot "tensorflow-opgen" super.tensorflow-opgen;
35
36 tensorflow-ops = setTensorflowSourceRoot "tensorflow-ops" super.tensorflow-ops;
37}