tjh.dev
1{ lib, stdenv, fetchFromGitHub, llvmPackages, ncurses, cmake, libxml2
2, symlinkJoin, breakpointHook, cudaPackages, enableCUDA ? false
3, libobjc, Cocoa, Foundation
4}:
5
6let
7 luajitRev = "50936d784474747b4569d988767f1b5bab8bb6d0";
8 luajitBase = "LuaJIT-${luajitRev}";
9 luajitArchive = "${luajitBase}.tar.gz";
10 luajitSrc = fetchFromGitHub {
11 owner = "LuaJIT";
12 repo = "LuaJIT";
13 rev = luajitRev;
14 sha256 = "1g87pl014b5v6z2nnhiwn3wf405skawszfr5wdzyfbx00j3kgxd0";
15 };
16
17 llvmMerged = symlinkJoin {
18 name = "llvmClangMerged";
19 paths = with llvmPackages; [
20 llvm.out
21 llvm.dev
22 llvm.lib
23 clang-unwrapped.out
24 clang-unwrapped.dev
25 clang-unwrapped.lib
26 ];
27 };
28
29 cuda = cudaPackages.cudatoolkit_11;
30
31 clangVersion = llvmPackages.clang-unwrapped.version;
32
33in stdenv.mkDerivation rec {
34 pname = "terra";
35 version = "1.1.0";
36
37 src = fetchFromGitHub {
38 owner = "terralang";
39 repo = "terra";
40 rev = "release-${version}";
41 sha256 = "0v9vpxcp9ybwnfljskqn41vjq7c0srdfv7qs890a6480pnk4kavd";
42 };
43
44 nativeBuildInputs = [ cmake ];
45 buildInputs = [ llvmMerged ncurses libxml2 ]
46 ++ lib.optionals enableCUDA [ cuda ]
47 ++ lib.optionals stdenv.isDarwin [ libobjc Cocoa Foundation ];
48
49 cmakeFlags = [
50 "-DHAS_TERRA_VERSION=0"
51 "-DTERRA_VERSION=${version}"
52 "-DTERRA_LUA=luajit"
53 "-DTERRA_SKIP_LUA_DOWNLOAD=ON"
54 "-DCLANG_RESOURCE_DIR=${llvmMerged}/lib/clang/${clangVersion}"
55 ] ++ lib.optional enableCUDA "-DTERRA_ENABLE_CUDA=ON";
56
57 doCheck = true;
58 hardeningDisable = [ "fortify" ];
59 outputs = [ "bin" "dev" "out" "static" ];
60
61 patches = [ ./nix-cflags.patch ];
62
63 postPatch = ''
64 substituteInPlace src/terralib.lua \
65 --subst-var-by NIX_LIBC_INCLUDE ${lib.getDev stdenv.cc.libc}/include
66 '';
67
68 preConfigure = ''
69 mkdir -p build
70 ln -s ${luajitSrc} build/${luajitBase}
71 tar --mode="a+rwX" -chzf build/${luajitArchive} -C build ${luajitBase}
72 rm build/${luajitBase}
73 '';
74
75 installPhase = ''
76 install -Dm755 -t $bin/bin bin/terra
77 install -Dm755 -t $out/lib lib/terra${stdenv.hostPlatform.extensions.sharedLibrary}
78 install -Dm644 -t $static/lib lib/libterra_s.a
79
80 mkdir -pv $dev/include
81 cp -rv include/terra $dev/include
82 '';
83
84 meta = with lib; {
85 description = "A low-level counterpart to Lua";
86 homepage = "https://terralang.org/";
87 platforms = platforms.all;
88 maintainers = with maintainers; [ jb55 seylerius thoughtpolice elliottslaughter ];
89 license = licenses.mit;
90 # never built on aarch64-darwin since first introduction in nixpkgs
91 broken = stdenv.isDarwin && stdenv.isAarch64;
92 };
93}