tjh.dev
1{ lib, buildPackages, callPackage, cargo-auditable, stdenv, runCommand }@prev:
2
3{ rustc
4, cargo
5, cargo-auditable ? prev.cargo-auditable
6, stdenv ? prev.stdenv
7, ...
8}:
9
10rec {
11 rust = {
12 rustc = lib.warn "rustPlatform.rust.rustc is deprecated. Use rustc instead." rustc;
13 cargo = lib.warn "rustPlatform.rust.cargo is deprecated. Use cargo instead." cargo;
14 };
15
16 fetchCargoTarball = buildPackages.callPackage ../../../build-support/rust/fetch-cargo-tarball {
17 git = buildPackages.gitMinimal;
18 inherit cargo;
19 };
20
21 buildRustPackage = callPackage ../../../build-support/rust/build-rust-package {
22 inherit stdenv cargoBuildHook cargoCheckHook cargoInstallHook cargoNextestHook cargoSetupHook
23 fetchCargoTarball importCargoLock rustc cargo cargo-auditable;
24 };
25
26 importCargoLock = buildPackages.callPackage ../../../build-support/rust/import-cargo-lock.nix { inherit cargo; };
27
28 rustcSrc = callPackage ./rust-src.nix {
29 inherit runCommand rustc;
30 };
31
32 rustLibSrc = callPackage ./rust-lib-src.nix {
33 inherit runCommand rustc;
34 };
35
36 # Hooks
37 inherit (callPackage ../../../build-support/rust/hooks {
38 inherit stdenv cargo rustc;
39 }) cargoBuildHook cargoCheckHook cargoInstallHook cargoNextestHook cargoSetupHook maturinBuildHook bindgenHook;
40}