tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, llvm_meta, version, fetch, cmake, python3, libllvm, libcxxabi
2, doFakeLibgcc ? stdenv.hostPlatform.isFreeBSD
3}:
4
5let
6
7 useLLVM = stdenv.hostPlatform.useLLVM or false;
8 bareMetal = stdenv.hostPlatform.parsed.kernel.name == "none";
9 haveLibc = stdenv.cc.libc != null;
10 inherit (stdenv.hostPlatform) isMusl;
11
12in
13
14stdenv.mkDerivation {
15 pname = "compiler-rt" + lib.optionalString (haveLibc) "-libc";
16 inherit version;
17 src = fetch "compiler-rt" "0dqqf8f930l8gag4d9qjgn1n0pj0nbv2anviqqhdi1rkhas8z0hi";
18
19 nativeBuildInputs = [ cmake python3 libllvm.dev ];
20 buildInputs = lib.optional stdenv.hostPlatform.isDarwin libcxxabi;
21
22 env.NIX_CFLAGS_COMPILE = toString [
23 "-DSCUDO_DEFAULT_OPTIONS=DeleteSizeMismatch=0:DeallocationTypeMismatch=0"
24 ];
25
26 cmakeFlags = [
27 "-DCOMPILER_RT_DEFAULT_TARGET_ONLY=ON"
28 "-DCMAKE_C_COMPILER_TARGET=${stdenv.hostPlatform.config}"
29 "-DCMAKE_ASM_COMPILER_TARGET=${stdenv.hostPlatform.config}"
30 ] ++ lib.optionals (useLLVM || bareMetal || isMusl) [
31 "-DCOMPILER_RT_BUILD_SANITIZERS=OFF"
32 "-DCOMPILER_RT_BUILD_XRAY=OFF"
33 "-DCOMPILER_RT_BUILD_LIBFUZZER=OFF"
34 ] ++ lib.optionals (useLLVM || bareMetal) [
35 "-DCOMPILER_RT_BUILD_PROFILE=OFF"
36 ] ++ lib.optionals ((useLLVM || bareMetal) && !haveLibc) [
37 "-DCMAKE_C_COMPILER_WORKS=ON"
38 "-DCMAKE_CXX_COMPILER_WORKS=ON"
39 "-DCOMPILER_RT_BAREMETAL_BUILD=ON"
40 "-DCMAKE_SIZEOF_VOID_P=${toString (stdenv.hostPlatform.parsed.cpu.bits / 8)}"
41 ] ++ lib.optionals (useLLVM) [
42 "-DCOMPILER_RT_BUILD_BUILTINS=ON"
43 #https://stackoverflow.com/questions/53633705/cmake-the-c-compiler-is-not-able-to-compile-a-simple-test-program
44 "-DCMAKE_TRY_COMPILE_TARGET_TYPE=STATIC_LIBRARY"
45 ] ++ lib.optionals (bareMetal) [
46 "-DCOMPILER_RT_OS_DIR=baremetal"
47 ] ++ lib.optionals (stdenv.hostPlatform.isDarwin) [
48 # The compiler-rt build infrastructure sniffs supported platforms on Darwin
49 # and finds i386;x86_64;x86_64h. We only build for x86_64, so linking fails
50 # when it tries to use libc++ and libc++api for i386.
51 "-DDARWIN_osx_ARCHS=${stdenv.hostPlatform.darwinArch}"
52 ];
53
54 outputs = [ "out" "dev" ];
55
56 patches = [
57 # https://github.com/llvm/llvm-project/commit/947f9692440836dcb8d88b74b69dd379d85974ce
58 ../../common/compiler-rt/glibc.patch
59 ./codesign.patch # Revert compiler-rt commit that makes codesign mandatory
60 ./gnu-install-dirs.patch
61 ../../common/compiler-rt/libsanitizer-no-cyclades-9.patch
62 ] ++ lib.optional (useLLVM) ./crtbegin-and-end.patch
63 ++ lib.optional stdenv.hostPlatform.isAarch32 ./armv7l.patch;
64
65 # TSAN requires XPC on Darwin, which we have no public/free source files for. We can depend on the Apple frameworks
66 # to get it, but they're unfree. Since LLVM is rather central to the stdenv, we patch out TSAN support so that Hydra
67 # can build this. If we didn't do it, basically the entire nixpkgs on Darwin would have an unfree dependency and we'd
68 # get no binary cache for the entire platform. If you really find yourself wanting the TSAN, make this controllable by
69 # a flag and turn the flag off during the stdenv build.
70 postPatch = lib.optionalString (!stdenv.isDarwin) ''
71 substituteInPlace cmake/builtin-config-ix.cmake \
72 --replace 'set(X86 i386)' 'set(X86 i386 i486 i586 i686)'
73 '' + lib.optionalString stdenv.isDarwin ''
74 substituteInPlace cmake/config-ix.cmake \
75 --replace 'set(COMPILER_RT_HAS_TSAN TRUE)' 'set(COMPILER_RT_HAS_TSAN FALSE)'
76 '' + lib.optionalString (useLLVM) ''
77 substituteInPlace lib/builtins/int_util.c \
78 --replace "#include <stdlib.h>" ""
79 substituteInPlace lib/builtins/clear_cache.c \
80 --replace "#include <assert.h>" ""
81 substituteInPlace lib/builtins/cpu_model.c \
82 --replace "#include <assert.h>" ""
83 '';
84
85 preConfigure = lib.optionalString (useLLVM && !haveLibc) ''
86 cmakeFlagsArray+=(-DCMAKE_C_FLAGS="-nodefaultlibs -ffreestanding")
87 '';
88
89 # Hack around weird upsream RPATH bug
90 postInstall = lib.optionalString (stdenv.hostPlatform.isDarwin || stdenv.hostPlatform.isWasm) ''
91 ln -s "$out/lib"/*/* "$out/lib"
92 '' + lib.optionalString (useLLVM) ''
93 ln -s $out/lib/*/clang_rt.crtbegin-*.o $out/lib/crtbegin.o
94 ln -s $out/lib/*/clang_rt.crtend-*.o $out/lib/crtend.o
95 ln -s $out/lib/*/clang_rt.crtbegin_shared-*.o $out/lib/crtbeginS.o
96 ln -s $out/lib/*/clang_rt.crtend_shared-*.o $out/lib/crtendS.o
97 '' + lib.optionalString doFakeLibgcc ''
98 ln -s $out/lib/freebsd/libclang_rt.builtins-*.a $out/lib/libgcc.a
99 '';
100
101 meta = llvm_meta // {
102 homepage = "https://compiler-rt.llvm.org/";
103 description = "Compiler runtime libraries";
104 longDescription = ''
105 The compiler-rt project provides highly tuned implementations of the
106 low-level code generator support routines like "__fixunsdfdi" and other
107 calls generated when a target doesn't have a short sequence of native
108 instructions to implement a core IR operation. It also provides
109 implementations of run-time libraries for dynamic testing tools such as
110 AddressSanitizer, ThreadSanitizer, MemorySanitizer, and DataFlowSanitizer.
111 '';
112 # "All of the code in the compiler-rt project is dual licensed under the MIT
113 # license and the UIUC License (a BSD-like license)":
114 license = with lib.licenses; [ mit ncsa ];
115 broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
116 };
117}