tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, llvm_meta, version, fetch, cmake, python3, libllvm, libcxxabi, libxcrypt
2, doFakeLibgcc ? stdenv.hostPlatform.isFreeBSD
3}:
4
5let
6
7 useLLVM = stdenv.hostPlatform.useLLVM or false;
8 bareMetal = stdenv.hostPlatform.parsed.kernel.name == "none";
9 haveLibc = stdenv.cc.libc != null;
10 inherit (stdenv.hostPlatform) isMusl;
11
12in
13
14stdenv.mkDerivation {
15 pname = "compiler-rt" + lib.optionalString (haveLibc) "-libc";
16 inherit version;
17 src = fetch "compiler-rt" "1yjqjri753w0fzmxcyz687nvd97sbc9rsqrxzpq720na47hwh3fr";
18
19 nativeBuildInputs = [ cmake python3 libllvm.dev ];
20 buildInputs = lib.optional stdenv.hostPlatform.isDarwin libcxxabi;
21
22 env.NIX_CFLAGS_COMPILE = toString [
23 "-DSCUDO_DEFAULT_OPTIONS=DeleteSizeMismatch=0:DeallocationTypeMismatch=0"
24 ];
25
26 cmakeFlags = [
27 "-DCOMPILER_RT_DEFAULT_TARGET_ONLY=ON"
28 "-DCMAKE_C_COMPILER_TARGET=${stdenv.hostPlatform.config}"
29 "-DCMAKE_ASM_COMPILER_TARGET=${stdenv.hostPlatform.config}"
30 ] ++ lib.optionals (haveLibc && stdenv.hostPlatform.isGnu) [
31 "-DSANITIZER_COMMON_CFLAGS=-I${libxcrypt}/include"
32 ] ++ lib.optionals (useLLVM || bareMetal || isMusl) [
33 "-DCOMPILER_RT_BUILD_SANITIZERS=OFF"
34 "-DCOMPILER_RT_BUILD_XRAY=OFF"
35 "-DCOMPILER_RT_BUILD_LIBFUZZER=OFF"
36 ] ++ lib.optionals (useLLVM || bareMetal) [
37 "-DCOMPILER_RT_BUILD_PROFILE=OFF"
38 ] ++ lib.optionals ((useLLVM || bareMetal) && !haveLibc) [
39 "-DCMAKE_C_COMPILER_WORKS=ON"
40 "-DCMAKE_CXX_COMPILER_WORKS=ON"
41 "-DCOMPILER_RT_BAREMETAL_BUILD=ON"
42 "-DCMAKE_SIZEOF_VOID_P=${toString (stdenv.hostPlatform.parsed.cpu.bits / 8)}"
43 ] ++ lib.optionals (useLLVM) [
44 "-DCOMPILER_RT_BUILD_BUILTINS=ON"
45 #https://stackoverflow.com/questions/53633705/cmake-the-c-compiler-is-not-able-to-compile-a-simple-test-program
46 "-DCMAKE_TRY_COMPILE_TARGET_TYPE=STATIC_LIBRARY"
47 ] ++ lib.optionals (bareMetal) [
48 "-DCOMPILER_RT_OS_DIR=baremetal"
49 ] ++ lib.optionals (stdenv.hostPlatform.isDarwin) [
50 "-DDARWIN_macosx_OVERRIDE_SDK_VERSION=ON"
51 "-DDARWIN_osx_ARCHS=${stdenv.hostPlatform.darwinArch}"
52 "-DDARWIN_osx_BUILTIN_ARCHS=${stdenv.hostPlatform.darwinArch}"
53 ];
54
55 outputs = [ "out" "dev" ];
56
57 patches = [
58 ./codesign.patch # Revert compiler-rt commit that makes codesign mandatory
59 ./find-darwin-sdk-version.patch # don't test for macOS being >= 10.15
60 ./gnu-install-dirs.patch
61 ../../common/compiler-rt/libsanitizer-no-cyclades-11.patch
62 ./X86-support-extension.patch # backported from LLVM 11
63 # Fix build on armv6l
64 ../../common/compiler-rt/armv6-mcr-dmb.patch
65 ../../common/compiler-rt/armv6-sync-ops-no-thumb.patch
66 ../../common/compiler-rt/armv6-no-ldrexd-strexd.patch
67 ] ++ lib.optional stdenv.hostPlatform.isAarch32 ./armv7l.patch;
68
69 # TSAN requires XPC on Darwin, which we have no public/free source files for. We can depend on the Apple frameworks
70 # to get it, but they're unfree. Since LLVM is rather central to the stdenv, we patch out TSAN support so that Hydra
71 # can build this. If we didn't do it, basically the entire nixpkgs on Darwin would have an unfree dependency and we'd
72 # get no binary cache for the entire platform. If you really find yourself wanting the TSAN, make this controllable by
73 # a flag and turn the flag off during the stdenv build.
74 postPatch = lib.optionalString (!stdenv.isDarwin) ''
75 substituteInPlace cmake/builtin-config-ix.cmake \
76 --replace 'set(X86 i386)' 'set(X86 i386 i486 i586 i686)'
77 substituteInPlace cmake/config-ix.cmake \
78 --replace 'set(X86 i386)' 'set(X86 i386 i486 i586 i686)'
79 '' + lib.optionalString stdenv.isDarwin ''
80 substituteInPlace cmake/config-ix.cmake \
81 --replace 'set(COMPILER_RT_HAS_TSAN TRUE)' 'set(COMPILER_RT_HAS_TSAN FALSE)'
82 '' + lib.optionalString (useLLVM) ''
83 substituteInPlace lib/builtins/int_util.c \
84 --replace "#include <stdlib.h>" ""
85 substituteInPlace lib/builtins/clear_cache.c \
86 --replace "#include <assert.h>" ""
87 substituteInPlace lib/builtins/cpu_model.c \
88 --replace "#include <assert.h>" ""
89 '';
90
91 preConfigure = lib.optionalString (useLLVM && !haveLibc) ''
92 cmakeFlagsArray+=(-DCMAKE_C_FLAGS="-nodefaultlibs -ffreestanding")
93 '';
94
95 # Hack around weird upsream RPATH bug
96 postInstall = lib.optionalString (stdenv.hostPlatform.isDarwin || stdenv.hostPlatform.isWasm) ''
97 ln -s "$out/lib"/*/* "$out/lib"
98 '' + lib.optionalString (useLLVM) ''
99 ln -s $out/lib/*/clang_rt.crtbegin-*.o $out/lib/crtbegin.o
100 ln -s $out/lib/*/clang_rt.crtend-*.o $out/lib/crtend.o
101 ln -s $out/lib/*/clang_rt.crtbegin-*.o $out/lib/crtbeginS.o
102 ln -s $out/lib/*/clang_rt.crtend-*.o $out/lib/crtendS.o
103 ln -s $out/lib/*/clang_rt.crtbegin_shared-*.o $out/lib/crtbeginS.o
104 ln -s $out/lib/*/clang_rt.crtend_shared-*.o $out/lib/crtendS.o
105 ''
106 # See https://reviews.llvm.org/D37278 for why android exception
107 + lib.optionalString (stdenv.hostPlatform.isx86_32 && !stdenv.hostPlatform.isAndroid) ''
108 for f in $out/lib/*/*builtins-i?86*; do
109 ln -s "$f" $(echo "$f" | sed -e 's/builtins-i.86/builtins-i386/')
110 done
111 '' + lib.optionalString doFakeLibgcc ''
112 ln -s $out/lib/freebsd/libclang_rt.builtins-*.a $out/lib/libgcc.a
113 '';
114
115 meta = llvm_meta // {
116 homepage = "https://compiler-rt.llvm.org/";
117 description = "Compiler runtime libraries";
118 longDescription = ''
119 The compiler-rt project provides highly tuned implementations of the
120 low-level code generator support routines like "__fixunsdfdi" and other
121 calls generated when a target doesn't have a short sequence of native
122 instructions to implement a core IR operation. It also provides
123 implementations of run-time libraries for dynamic testing tools such as
124 AddressSanitizer, ThreadSanitizer, MemorySanitizer, and DataFlowSanitizer.
125 '';
126 # "All of the code in the compiler-rt project is dual licensed under the MIT
127 # license and the UIUC License (a BSD-like license)":
128 license = with lib.licenses; [ mit ncsa ];
129 broken = stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isAarch64;
130 };
131}