tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ fetchFromGitHub
2, fetchpatch
3, glib
4, gobject-introspection
5, meson
6, ninja
7, pkg-config
8, lib
9, stdenv
10, wrapGAppsHook
11, libxml2
12, gtk3
13, gvfs
14, cinnamon-desktop
15, xapp
16, libexif
17, exempi
18, intltool
19, shared-mime-info
20, cinnamon-translations
21, libgsf
22}:
23
24stdenv.mkDerivation rec {
25 pname = "nemo";
26 version = "5.6.5";
27
28 src = fetchFromGitHub {
29 owner = "linuxmint";
30 repo = pname;
31 rev = version;
32 sha256 = "sha256-HdDe2VE9LQqiwFrUSIctOi/ffNOmLy6SyG30EL8UA5Q=";
33 };
34
35 patches = [
36 # Load extensions from NEMO_EXTENSION_DIR environment variable
37 # https://github.com/NixOS/nixpkgs/issues/78327
38 ./load-extensions-from-env.patch
39 ];
40
41 outputs = [ "out" "dev" ];
42
43 buildInputs = [
44 glib
45 gtk3
46 cinnamon-desktop
47 libxml2
48 xapp
49 libexif
50 exempi
51 gvfs
52 gobject-introspection
53 libgsf
54 ];
55
56 nativeBuildInputs = [
57 meson
58 pkg-config
59 ninja
60 wrapGAppsHook
61 intltool
62 shared-mime-info
63 ];
64
65 mesonFlags = [
66 # use locales from cinnamon-translations
67 "--localedir=${cinnamon-translations}/share/locale"
68 ];
69
70 preFixup = ''
71 # Used for some non-fd.o icons (e.g. xapp-text-case-symbolic)
72 gappsWrapperArgs+=(
73 --prefix XDG_DATA_DIRS : "${xapp}/share"
74 )
75 '';
76
77 # Taken from libnemo-extension.pc.
78 passthru.extensiondir = "lib/nemo/extensions-3.0";
79
80 meta = with lib; {
81 homepage = "https://github.com/linuxmint/nemo";
82 description = "File browser for Cinnamon";
83 license = [ licenses.gpl2 licenses.lgpl2 ];
84 platforms = platforms.linux;
85 maintainers = teams.cinnamon.members;
86 mainProgram = "nemo";
87 };
88}
89