tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenvNoCC, fetchzip, version ? "3.300" }:
2
3let
4 new = lib.versionAtLeast version "3.000";
5 hash = {
6 "2.100" = "sha256-d2UyOOOnmE1afCwyIrM1bL3lQC7XRwh03hzetk/4V30=";
7 "3.300" = "sha256-LaaA6DWAE2dcwVVX4go9cJaiuwI6efYbPk82ym3W3IY=";
8 }."${version}";
9 pname = "scheherazade${lib.optionalString new "-new"}";
10in
11stdenvNoCC.mkDerivation rec {
12 inherit pname version;
13
14 src = fetchzip {
15 url = "http://software.sil.org/downloads/r/scheherazade/Scheherazade${lib.optionalString new "New"}-${version}.zip";
16 inherit hash;
17 };
18
19 installPhase = ''
20 runHook preInstall
21
22 install -Dm644 *.ttf -t $out/share/fonts/truetype
23 install -Dm644 FONTLOG.txt README.txt -t $out/share/doc
24 cp -r documentation $out/share/doc/
25
26 runHook postInstall
27 '';
28
29 meta = with lib; {
30 homepage = "https://software.sil.org/scheherazade/";
31 description = "A font designed in a similar style to traditional Naskh typefaces";
32 longDescription = ''
33
34 Scheherazade${lib.optionalString new " New"}, named after the heroine of
35 the classic Arabian Nights tale, is designed in a similar style to
36 traditional typefaces such as Monotype Naskh, extended to cover the
37 Unicode Arabic repertoire through Unicode ${if new then "14.0" else "8.0"}.
38
39 Scheherazade provides a “simplified” rendering of Arabic script, using
40 basic connecting glyphs but not including a wide variety of additional
41 ligatures or contextual alternates (only the required lam-alef
42 ligatures). This simplified style is often preferred for clarity,
43 especially in non-Arabic languages, but may not be considered appropriate
44 in situations where a more elaborate style of calligraphy is preferred.
45
46 This package contains the regular and bold styles for the Scheherazade
47 font family, along with documentation.
48 '';
49 downloadPage = "https://software.sil.org/scheherazade/download/";
50 license = licenses.ofl;
51 platforms = platforms.all;
52 };
53}