tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenvNoCC, fetchzip }:
2
3let
4 version = "1.3.3";
5
6 mkPretendard = { pname, typeface, hash }:
7 stdenvNoCC.mkDerivation {
8 inherit pname version;
9
10 src = fetchzip {
11 url = "https://github.com/orioncactus/pretendard/releases/download/v${version}/${typeface}-${version}.zip";
12 stripRoot = false;
13 inherit hash;
14 };
15
16 installPhase = ''
17 runHook preInstall
18
19 install -Dm644 public/static/*.otf -t $out/share/fonts/opentype
20
21 runHook postInstall
22 '';
23
24 meta = with lib; {
25 homepage = "https://github.com/orioncactus/pretendard";
26 description = "An alternative font to system-ui for all platforms";
27 license = licenses.ofl;
28 platforms = platforms.all;
29 maintainers = with maintainers; [ sudosubin ];
30 };
31 };
32
33in
34{
35 pretendard = mkPretendard {
36 pname = "pretendard";
37 typeface = "Pretendard";
38 hash = "sha256-xCEZlwTPhrNIO6WODl55wo2oin+iMYOL/rVaEybpzr0=";
39 };
40
41 pretendard-jp = mkPretendard {
42 pname = "pretendard-jp";
43 typeface = "PretendardJP";
44 hash = "sha256-x0G7ULzkIJqZlK995+wWKHXZdWryUTRouGTa5LsJQzk=";
45 };
46
47 pretendard-std = mkPretendard {
48 pname = "pretendard-std";
49 typeface = "PretendardStd";
50 hash = "sha256-/I8LZhFB86/+o+IzUP+bSIq7scKPOL7k/6/Bom0ZSqg=";
51 };
52}