tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, stdenv, fetchFromGitHub, pkg-config, meson, ninja, xxd, gettext, intltool
2, gtk3, lcms2, exiv2, libchamplain, clutter-gtk, ffmpegthumbnailer, fbida
3, libarchive, djvulibre, libheif, openjpeg, libjxl, libraw, lua5_3, poppler
4, gspell, libtiff, libwebp
5, wrapGAppsHook, fetchpatch, doxygen
6, nix-update-script
7}:
8
9stdenv.mkDerivation rec {
10 pname = "geeqie";
11 version = "2.0.1";
12
13 src = fetchFromGitHub {
14 owner = "BestImageViewer";
15 repo = "geeqie";
16 rev = "v${version}";
17 sha256 = "sha256-0GOX77vZ4KZkvwnR1vlv52tlbR+ciwl3ycxbOIcDOqU=";
18 };
19
20 postPatch = ''
21 patchShebangs .
22 # libtiff detection is broken and looks for liblibtiff...
23 # fixed upstream, to remove for 2.1
24 substituteInPlace meson.build --replace 'libtiff' 'tiff'
25 '';
26
27 nativeBuildInputs =
28 [ pkg-config gettext intltool
29 wrapGAppsHook doxygen
30 meson ninja xxd
31 ];
32
33 buildInputs = [
34 gtk3 lcms2 exiv2 libchamplain clutter-gtk ffmpegthumbnailer fbida
35 libarchive djvulibre libheif openjpeg libjxl libraw lua5_3 poppler
36 gspell libtiff libwebp
37 ];
38
39 postInstall = ''
40 # Allow geeqie to find exiv2 and exiftran, necessary to
41 # losslessly rotate JPEG images.
42 sed -i $out/lib/geeqie/geeqie-rotate \
43 -e '1 a export PATH=${lib.makeBinPath [ exiv2 fbida ]}:$PATH'
44 '';
45
46 enableParallelBuilding = true;
47
48 passthru = {
49 updateScript = nix-update-script { };
50 };
51
52 meta = with lib; {
53 description = "Lightweight GTK based image viewer";
54
55 longDescription =
56 ''
57 Geeqie is a lightweight GTK based image viewer for Unix like
58 operating systems. It features: EXIF, IPTC and XMP metadata
59 browsing and editing interoperability; easy integration with other
60 software; geeqie works on files and directories, there is no need to
61 import images; fast preview for many raw image formats; tools for
62 image comparison, sorting and managing photo collection. Geeqie was
63 initially based on GQview.
64 '';
65
66 license = licenses.gpl2Plus;
67
68 homepage = "https://www.geeqie.org/";
69
70 maintainers = with maintainers; [ jfrankenau pSub markus1189 ];
71 platforms = platforms.gnu ++ platforms.linux;
72 };
73}