tjh.dev
1{ callPackage, lib, stdenv, fetchurl, jre, makeWrapper }:
2
3let this = stdenv.mkDerivation rec {
4 version = "6.6.0";
5 pname = "openapi-generator-cli";
6
7 jarfilename = "${pname}-${version}.jar";
8
9 nativeBuildInputs = [
10 makeWrapper
11 ];
12
13 src = fetchurl {
14 url = "mirror://maven/org/openapitools/${pname}/${version}/${jarfilename}";
15 sha256 = "sha256-lxj/eETolGLHXc2bIKNRNvbbJXv+G4dNseMALpneRgk=";
16 };
17
18 dontUnpack = true;
19
20 installPhase = ''
21 runHook preInstall
22
23 install -D "$src" "$out/share/java/${jarfilename}"
24
25 makeWrapper ${jre}/bin/java $out/bin/${pname} \
26 --add-flags "-jar $out/share/java/${jarfilename}"
27
28 runHook postInstall
29 '';
30
31 meta = with lib; {
32 description = "Allows generation of API client libraries (SDK generation), server stubs and documentation automatically given an OpenAPI Spec";
33 homepage = "https://github.com/OpenAPITools/openapi-generator";
34 changelog = "https://github.com/OpenAPITools/openapi-generator/releases/tag/v${version}";
35 sourceProvenance = with sourceTypes; [ binaryBytecode ];
36 license = licenses.asl20;
37 maintainers = with maintainers; [ shou ];
38 };
39
40 passthru.tests.example = callPackage ./example.nix {
41 openapi-generator-cli = this;
42 };
43};
44in this