tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ lib, appimageTools, fetchurl, nodePackages }: let
2 pname = "flexoptix-app";
3 version = "5.13.4";
4
5 src = fetchurl {
6 name = "${pname}-${version}.AppImage";
7 url = "https://flexbox.reconfigure.me/download/electron/linux/x64/FLEXOPTIX%20App.${version}.AppImage";
8 hash = "sha256-W+9KmKZ1bPfQfv1DXCJrIswriw4ivBVZPW81tfvRBc0=";
9 };
10
11 udevRules = fetchurl {
12 url = "https://www.flexoptix.net/static/frontend/Flexoptix/default/en_US/files/99-tprogrammer.rules";
13 hash = "sha256-OZe5dV50xq99olImbo7JQxPjRd7hGyBIVwFvtR9cIVc=";
14 };
15
16 appimageContents = (appimageTools.extract { inherit pname version src; }).overrideAttrs (oA: {
17 buildCommand = ''
18 ${oA.buildCommand}
19
20 # Get rid of the autoupdater
21 ${nodePackages.asar}/bin/asar extract $out/resources/app.asar app
22 sed -i 's/async isUpdateAvailable.*/async isUpdateAvailable(updateInfo) { return false;/g' app/node_modules/electron-updater/out/AppUpdater.js
23 ${nodePackages.asar}/bin/asar pack app $out/resources/app.asar
24 '';
25 });
26
27in appimageTools.wrapAppImage {
28 inherit pname version;
29 src = appimageContents;
30
31 multiPkgs = null; # no 32bit needed
32 extraPkgs = { pkgs, ... }@args: [
33 pkgs.hidapi
34 ] ++ appimageTools.defaultFhsEnvArgs.multiPkgs args;
35
36 extraInstallCommands = ''
37 # Add desktop convencience stuff
38 mv $out/bin/{${pname}-*,${pname}}
39 install -Dm444 ${appimageContents}/flexoptix-app.desktop -t $out/share/applications
40 install -Dm444 ${appimageContents}/flexoptix-app.png -t $out/share/pixmaps
41 substituteInPlace $out/share/applications/flexoptix-app.desktop \
42 --replace 'Exec=AppRun' "Exec=$out/bin/${pname} --"
43
44 # Add udev rules
45 mkdir -p $out/lib/udev/rules.d
46 ln -s ${udevRules} $out/lib/udev/rules.d/99-tprogrammer.rules
47 '';
48
49 meta = {
50 description = "Configure FLEXOPTIX Universal Transceivers in seconds";
51 homepage = "https://www.flexoptix.net";
52 changelog = "https://www.flexoptix.net/en/flexoptix-app/?os=linux#flexapp__modal__changelog";
53 license = lib.licenses.unfree;
54 maintainers = with lib.maintainers; [ das_j ];
55 platforms = [ "x86_64-linux" ];
56 };
57}