tjh.dev
1{ lib, stdenv, fetchFromGitHub, postgresql, zeromq, openssl, libsodium, libkrb5 }:
2
3stdenv.mkDerivation rec {
4 pname = "pipelinedb";
5 version = "1.0.0-13";
6
7 src = fetchFromGitHub {
8 owner = "pipelinedb";
9 repo = pname;
10 rev = version;
11 sha256 = "1mnqpvx6g1r2n4kjrrx01vbdx7kvndfsbmm7zbzizjnjlyixz75f";
12 };
13
14 buildInputs = [ postgresql openssl zeromq libsodium libkrb5 ];
15
16 makeFlags = [ "USE_PGXS=1" ];
17
18 NIX_LDFLAGS = lib.optionalString stdenv.isDarwin "-lsodium";
19
20 preConfigure = ''
21 substituteInPlace Makefile \
22 --replace "/usr/lib/libzmq.a" "${zeromq}/lib/libzmq.a"
23 '';
24
25 installPhase = ''
26 mkdir -p $out/bin
27 install -D -t $out/lib/ pipelinedb.so
28 install -D -t $out/share/postgresql/extension {pipelinedb-*.sql,pipelinedb.control}
29 '';
30
31 meta = with lib; {
32 description = "High-performance time-series aggregation for PostgreSQL";
33 homepage = "https://www.pipelinedb.com/";
34 license = licenses.asl20;
35 platforms = postgresql.meta.platforms;
36 maintainers = [ maintainers.marsam ];
37 broken = versions.major postgresql.version != "11";
38 };
39}