tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{ fetchurl, lib, stdenv, autoreconfHook, libkrb5 }:
2
3stdenv.mkDerivation rec {
4 pname = "libtirpc";
5 version = "1.3.3";
6
7 src = fetchurl {
8 url = "http://git.linux-nfs.org/?p=steved/libtirpc.git;a=snapshot;h=0fb94eef5062d2657d75eee686fa47238fafa312;sf=tgz";
9 sha256 = "sha256-3P3xYKeAmLbBI4TdsG1VZBO7py9ktiwhXNtGsnryGNI=";
10 name = "${pname}-${version}.tar.gz";
11 };
12
13 outputs = [ "out" "dev" ];
14
15 KRB5_CONFIG = "${libkrb5.dev}/bin/krb5-config";
16 nativeBuildInputs = [ autoreconfHook ];
17 propagatedBuildInputs = [ libkrb5 ];
18
19 preConfigure = ''
20 sed -es"|/etc/netconfig|$out/etc/netconfig|g" -i doc/Makefile.in tirpc/netconfig.h
21 '';
22
23 preInstall = ''
24 mkdir -p $out/etc
25 '';
26
27 doCheck = true;
28
29 meta = with lib; {
30 homepage = "https://sourceforge.net/projects/libtirpc/";
31 description = "The transport-independent Sun RPC implementation (TI-RPC)";
32 license = licenses.bsd3;
33 platforms = platforms.linux;
34 maintainers = with maintainers; [ abbradar ];
35 longDescription = ''
36 Currently, NFS commands use the SunRPC routines provided by the
37 glibc. These routines do not support IPv6 addresses. Ulrich
38 Drepper, who is the maintainer of the glibc, refuses any change in
39 the glibc concerning the RPC. He wants the RPC to become a separate
40 library. Other OS (NetBSD, FreeBSD, Solarix, HP-UX, AIX) have
41 migrated their SunRPC library to a TI-RPC (Transport Independent
42 RPC) implementation. This implementation allows the support of
43 other transports than UDP and TCP over IPv4. FreeBSD provides a
44 TI-RPC library ported from NetBSD with improvements. This library
45 already supports IPv6. So, the FreeBSD release 5.2.1 TI-RPC has
46 been ported to replace the SunRPC of the glibc.
47 '';
48 };
49}