tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 nixpkgs,
3 officialRelease,
4 pkgs ? import nixpkgs.outPath { },
5 nix ? pkgs.nix,
6 lib-tests ? import ../../lib/tests/release.nix { inherit pkgs; },
7}:
8
9pkgs.releaseTools.sourceTarball {
10 name = "nixpkgs-tarball";
11 src = nixpkgs;
12
13 inherit officialRelease;
14 version = pkgs.lib.fileContents ../../.version;
15 versionSuffix = "pre${
16 if nixpkgs ? lastModified then
17 builtins.substring 0 8 (nixpkgs.lastModifiedDate or nixpkgs.lastModified)
18 else
19 toString (nixpkgs.revCount or 0)
20 }.${nixpkgs.shortRev or "dirty"}";
21
22 buildInputs = with pkgs; [
23 nix.out
24 jq
25 lib-tests
26 brotli
27 ];
28
29 configurePhase = ''
30 eval "$preConfigure"
31 releaseName=nixpkgs-$VERSION$VERSION_SUFFIX
32 echo -n $VERSION_SUFFIX > .version-suffix
33 echo -n ${nixpkgs.rev or nixpkgs.shortRev or "dirty"} > .git-revision
34 echo "release name is $releaseName"
35 echo "git-revision is $(cat .git-revision)"
36 '';
37
38 dontUnpack = true;
39
40 dontBuild = false;
41
42 doCheck = true;
43
44 checkPhase = ''
45 echo "generating packages.json"
46
47 NIX_STATE_DIR=$TMPDIR NIX_PATH= nix-instantiate --eval --raw --expr "import $src/pkgs/top-level/packages-info.nix {}" | sed "s|$src/||g" | jq -c > packages.json
48
49 # Arbitrary number. The index has ~115k packages as of April 2024.
50 if [ $(jq -r '.packages | length' < packages.json) -lt 100000 ]; then
51 echo "ERROR: not enough packages in the search index, bailing out!"
52 exit 1
53 fi
54
55 packages=$out/packages.json.br
56
57 mkdir -p $out/nix-support
58 brotli -9 < packages.json > $packages
59 echo "file json-br $packages" >> $out/nix-support/hydra-build-products
60 '';
61
62 # --hard-dereference: reproducibility for src if auto-optimise-store = true
63 # Some context: https://github.com/NixOS/infra/issues/438
64 distPhase = ''
65 mkdir -p $out/tarballs
66 XZ_OPT="-T0" tar \
67 --create \
68 --xz \
69 --file=$out/tarballs/$releaseName.tar.xz \
70 --absolute-names \
71 --transform="s|^$src|$releaseName|g" \
72 --transform="s|^$(pwd)|$releaseName|g" \
73 --owner=0 \
74 --group=0 \
75 --numeric-owner \
76 --format=gnu \
77 --sort=name \
78 --mtime="@$SOURCE_DATE_EPOCH" \
79 --mode=ug+w \
80 --hard-dereference \
81 $src $(pwd)/{.version-suffix,.git-revision}
82 '';
83}