tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchgit,
5 libxml2,
6 libxslt,
7 docbook-xsl,
8 docbook_xml_dtd_44,
9 perlPackages,
10 makeWrapper,
11 perl, # for pod2man
12 cctools,
13 gitUpdater,
14}:
15
16stdenv.mkDerivation rec {
17 pname = "moreutils";
18 version = "0.70";
19
20 src = fetchgit {
21 url = "git://git.joeyh.name/moreutils";
22 tag = version;
23 hash = "sha256-71ACHzzk258U4q2L7GJ59mrMZG99M7nQkcH4gHafGP0=";
24 };
25
26 strictDeps = true;
27 nativeBuildInputs = [
28 makeWrapper
29 perl
30 libxml2
31 libxslt
32 docbook-xsl
33 docbook_xml_dtd_44
34 ];
35 buildInputs =
36 [
37 (perl.withPackages (p: [
38 p.IPCRun
39 p.TimeDate
40 p.TimeDuration
41 ]))
42 ]
43 ++ lib.optionals stdenv.hostPlatform.isDarwin [
44 cctools
45 ];
46
47 makeFlags = [
48 "CC=${stdenv.cc.targetPrefix}cc"
49 "DOCBOOKXSL=${docbook-xsl}/xml/xsl/docbook"
50 "INSTALL_BIN=install"
51 "PREFIX=${placeholder "out"}"
52 ];
53
54 passthru.updateScript = gitUpdater {
55 # No nicer place to find latest release.
56 url = "git://git.joeyh.name/moreutils";
57 };
58
59 meta = with lib; {
60 description = "Growing collection of the unix tools that nobody thought to write long ago when unix was young";
61 homepage = "https://joeyh.name/code/moreutils/";
62 maintainers = with maintainers; [
63 koral
64 pSub
65 ];
66 platforms = platforms.all;
67 license = licenses.gpl2Plus;
68 };
69}