tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 docbook_xml_dtd_44,
5 docbook_xml_dtd_45,
6 docbook_xsl,
7 asciidoctor,
8 fetchurl,
9 flex,
10 kmod,
11 libxslt,
12 nixosTests,
13 perl,
14 perlPackages,
15 systemd,
16 keyutils,
17
18 # drbd-utils are compiled twice, once with forOCF = true to extract
19 # its OCF definitions for use in the ocf-resource-agents derivation,
20 # then again with forOCF = false, where the ocf-resource-agents is
21 # provided as the OCF_ROOT.
22 forOCF ? false,
23 ocf-resource-agents,
24}:
25
26stdenv.mkDerivation rec {
27 pname = "drbd";
28 version = "9.27.0";
29
30 src = fetchurl {
31 url = "https://pkg.linbit.com/downloads/drbd/utils/${pname}-utils-${version}.tar.gz";
32 sha256 = "1qwdrjrgas8z8vc6c85xcrqaczjwyqd61yig01n44wa5z0j3v4aq";
33 };
34
35 nativeBuildInputs = [
36 flex
37 libxslt
38 docbook_xsl
39 asciidoctor
40 keyutils
41 ];
42
43 buildInputs = [
44 perl
45 perlPackages.Po4a
46 ];
47
48 configureFlags = [
49 "--libdir=${placeholder "out"}/lib"
50 "--sbindir=${placeholder "out"}/bin"
51 "--localstatedir=/var"
52 "--sysconfdir=/etc"
53 "--without-distro"
54 ];
55
56 makeFlags = [
57 "SOURCE_DATE_EPOCH=1"
58 "WANT_DRBD_REPRODUCIBLE_BUILD=1"
59 ] ++ lib.optional (!forOCF) "OCF_ROOT=${ocf-resource-agents}/usr/lib/ocf}";
60
61 installFlags = [
62 "prefix="
63 "DESTDIR=${placeholder "out"}"
64 "localstatedir=/var"
65 "DRBD_LIB_DIR=/var/lib"
66 "INITDIR=/etc/init.d"
67 "udevrulesdir=/etc/udev/rules.d"
68 "sysconfdir=/etc"
69 "sbindir=/bin"
70 "datadir="
71 "LIBDIR=/lib/drbd"
72 "mandir=/share/man"
73 ];
74
75 postPatch = ''
76 patchShebangs .
77 substituteInPlace user/v84/drbdadm_usage_cnt.c \
78 --replace '"/lib/drbd");' \
79 '"${placeholder "out"}/lib/drbd");'
80 substituteInPlace user/v9/drbdsetup_linux.c \
81 --replace 'ret = system("/sbin/modprobe drbd");' \
82 'ret = system("${kmod}/bin/modprobe drbd");'
83 substituteInPlace user/v84/drbdsetup.c \
84 --replace 'system("/sbin/modprobe drbd")' \
85 'system("${kmod}/bin/modprobe drbd")'
86 substituteInPlace documentation/ra2refentry.xsl \
87 --replace "http://www.oasis-open.org/docbook/xml/4.4/docbookx.dtd" \
88 "${docbook_xml_dtd_44}/xml/dtd/docbook/docbookx.dtd"
89 function patch_docbook45() {
90 substituteInPlace $1 \
91 --replace "http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd" \
92 "${docbook_xml_dtd_45}/xml/dtd/docbook/docbookx.dtd"
93 }
94 patch_docbook45 documentation/v9/drbd.conf.xml.in
95 patch_docbook45 documentation/v9/drbdsetup.xml.in
96 patch_docbook45 documentation/v84/drbdsetup.xml
97 patch_docbook45 documentation/v84/drbd.conf.xml
98 # The ja documentation is disabled because:
99 # make[1]: Entering directory '/build/drbd-utils-9.16.0/documentation/ja/v84'
100 # /nix/store/wyx2nn2pjcn50lc95c6qgsgm606rn0x2-perl5.32.1-po4a-0.62/bin/po4a-translate -f docbook -M utf-8 -L utf-8 -keep 0 -m ../../v84/drbdsetup.xml -p drbdsetup.xml.po -l drbdsetup.xml
101 # Use of uninitialized value $args[1] in sprintf at /nix/store/wyx2nn2pjcn50lc95c6qgsgm606rn0x2-perl5.32.1-po4a-0.62/lib/perl5/site_perl/Locale/Po4a/Common.pm line 134.
102 # Invalid po file drbdsetup.xml.po:
103 substituteInPlace Makefile.in \
104 --replace 'DOC_DIRS := documentation/v9 documentation/ja/v9' \
105 'DOC_DIRS := documentation/v9' \
106 --replace 'DOC_DIRS += documentation/v84 documentation/ja/v84' \
107 'DOC_DIRS += documentation/v84' \
108 --replace '$(MAKE) -C documentation/ja/v9 doc' \
109 "" \
110 --replace '$(MAKE) -C documentation/ja/v84 doc' \
111 ""
112 substituteInPlace user/v9/drbdtool_common.c \
113 --replace 'add_component_to_path("/lib/drbd");' \
114 'add_component_to_path("${placeholder "out"}/lib/drbd");'
115 '';
116
117 preConfigure = ''
118 export PATH=${systemd}/sbin:$PATH
119 '';
120
121 enableParallelBuilding = true;
122
123 passthru.tests.drbd = nixosTests.drbd;
124
125 meta = with lib; {
126 homepage = "https://linbit.com/drbd/";
127 description = "Distributed Replicated Block Device, a distributed storage system for Linux (userspace utilities)";
128 license = licenses.gpl2Plus;
129 platforms = platforms.linux;
130 maintainers = with maintainers; [
131 ryantm
132 astro
133 birkb
134 ];
135 longDescription = ''
136 DRBD is a software-based, shared-nothing, replicated storage solution
137 mirroring the content of block devices (hard disks, partitions, logical volumes, and so on) between hosts.
138 '';
139 };
140}