tjh.dev
1{
2 stdenv,
3 lib,
4 fetchFromGitHub,
5 autoreconfHook,
6 libX11,
7 pkg-config,
8 libXext,
9 libdrm,
10 libXfixes,
11 wayland,
12 wayland-scanner,
13 libffi,
14 libGL,
15 mesa,
16 minimal ? false,
17 libva1-minimal,
18}:
19
20stdenv.mkDerivation rec {
21 pname = "libva" + lib.optionalString minimal "-minimal";
22 # nixpkgs-update: no auto update
23 version = "1.8.3";
24
25 src = fetchFromGitHub {
26 owner = "intel";
27 repo = "libva";
28 rev = version;
29 sha256 = "sha256-ur59cqdZqXIY2dDUSie9XsxyRomVBxIW2IVKAgWYC38=";
30 };
31
32 outputs = [
33 "dev"
34 "out"
35 ];
36
37 nativeBuildInputs = [
38 autoreconfHook
39 pkg-config
40 wayland-scanner
41 ];
42
43 buildInputs =
44 [ libdrm ]
45 ++ lib.optionals (!minimal) [
46 libva1-minimal
47 libX11
48 libXext
49 libXfixes
50 wayland
51 libffi
52 libGL
53 ];
54 # TODO: share libs between minimal and !minimal - perhaps just symlink them
55
56 # Add FHS paths for non-NixOS applications.
57 configureFlags =
58 lib.optionals stdenv.hostPlatform.isLinux [
59 "--with-drivers-path=${mesa.driverLink}/lib/dri:/usr/lib/dri:/usr/lib32/dri"
60 ]
61 ++ lib.optionals (!minimal) [ "--enable-glx" ];
62
63 installFlags = [ "dummy_drv_video_ladir=$(out)/lib/dri" ];
64
65 meta = with lib; {
66 homepage = "https://www.freedesktop.org/wiki/Software/vaapi/";
67 license = licenses.mit;
68 description = "VAAPI library: Video Acceleration API";
69 platforms = platforms.unix;
70 maintainers = with maintainers; [ SuperSandro2000 ];
71 };
72}