tjh.dev
1{ pkgs }:
2
3with pkgs;
4
5let
6 openjfx11 = callPackage ../development/compilers/openjdk/openjfx/11 { };
7 openjfx17 = callPackage ../development/compilers/openjdk/openjfx/17 { };
8 openjfx19 = callPackage ../development/compilers/openjdk/openjfx/19 { };
9 openjfx20 = callPackage ../development/compilers/openjdk/openjfx/20 { };
10 openjfx21 = callPackage ../development/compilers/openjdk/openjfx/21 { };
11 openjfx22 = callPackage ../development/compilers/openjdk/openjfx/22 { };
12
13in {
14 inherit openjfx11 openjfx17 openjfx19 openjfx20 openjfx21 openjfx22;
15
16 compiler = let
17 mkOpenjdk = path-linux: path-darwin: args:
18 if stdenv.isLinux
19 then mkOpenjdkLinuxOnly path-linux args
20 else let
21 openjdk = callPackage path-darwin {};
22 in openjdk // { headless = openjdk; };
23
24 mkOpenjdkLinuxOnly = path-linux: args: let
25 openjdk = callPackage path-linux (args);
26 in assert stdenv.isLinux; openjdk // {
27 headless = openjdk.override { headless = true; };
28 };
29
30 in rec {
31 corretto11 = callPackage ../development/compilers/corretto/11.nix { };
32 corretto17 = callPackage ../development/compilers/corretto/17.nix { };
33 corretto19 = callPackage ../development/compilers/corretto/19.nix { };
34 corretto21 = callPackage ../development/compilers/corretto/21.nix { };
35
36 openjdk8-bootstrap = temurin-bin.jdk-8;
37
38 openjdk11-bootstrap = temurin-bin.jdk-11;
39
40 openjdk17-bootstrap = temurin-bin.jdk-17;
41
42 openjdk8 = mkOpenjdk
43 ../development/compilers/openjdk/8.nix
44 ../development/compilers/zulu/8.nix
45 { };
46
47 openjdk11 = mkOpenjdk
48 ../development/compilers/openjdk/11.nix
49 ../development/compilers/zulu/11.nix
50 { openjfx = openjfx11; };
51
52 openjdk17 = mkOpenjdk
53 ../development/compilers/openjdk/17.nix
54 ../development/compilers/zulu/17.nix
55 {
56 inherit openjdk17-bootstrap;
57 openjfx = openjfx17;
58 };
59
60 openjdk18 = mkOpenjdk
61 ../development/compilers/openjdk/18.nix
62 ../development/compilers/zulu/18.nix
63 {
64 openjdk18-bootstrap = temurin-bin.jdk-18;
65 openjfx = openjfx17;
66 };
67
68 openjdk19 = mkOpenjdk
69 ../development/compilers/openjdk/19.nix
70 ../development/compilers/zulu/19.nix
71 {
72 openjdk19-bootstrap = temurin-bin.jdk-19;
73 openjfx = openjfx19;
74 };
75
76 openjdk20 = mkOpenjdk
77 ../development/compilers/openjdk/20.nix
78 ../development/compilers/zulu/20.nix
79 {
80 openjdk20-bootstrap = temurin-bin.jdk-20;
81 openjfx = openjfx20;
82 };
83
84 openjdk21 = mkOpenjdk
85 ../development/compilers/openjdk/21.nix
86 ../development/compilers/zulu/21.nix
87 {
88 openjdk21-bootstrap = temurin-bin.jdk-21;
89 openjfx = openjfx21;
90 };
91
92 openjdk22 = mkOpenjdk
93 ../development/compilers/openjdk/22.nix
94 ../development/compilers/zulu/22.nix
95 {
96 openjdk22-bootstrap = temurin-bin.jdk-22;
97 openjfx = openjfx22;
98 };
99
100 temurin-bin = recurseIntoAttrs (callPackage (
101 if stdenv.isLinux
102 then ../development/compilers/temurin-bin/jdk-linux.nix
103 else ../development/compilers/temurin-bin/jdk-darwin.nix
104 ) {});
105
106 semeru-bin = recurseIntoAttrs (callPackage (
107 if stdenv.isLinux
108 then ../development/compilers/semeru-bin/jdk-linux.nix
109 else ../development/compilers/semeru-bin/jdk-darwin.nix
110 ) {});
111 };
112}
113// lib.optionalAttrs config.allowAliases {
114 jogl_2_4_0 = throw "'jogl_2_4_0' is renamed to/replaced by 'jogl'";
115 mavenfod = throw "'mavenfod' is renamed to/replaced by 'maven.buildMavenPackage'";
116}