tjh.dev
1{ lib, stdenv, fetchurl, cmake, python3, bison, openssl, readline, bzip2 }:
2
3stdenv.mkDerivation (finalAttrs: {
4 pname = "monetdb";
5 version = "11.49.11";
6
7 src = fetchurl {
8 url = "https://dev.monetdb.org/downloads/sources/archive/MonetDB-${finalAttrs.version}.tar.bz2";
9 hash = "sha256-tnGRNTx/SH7Yj8xvaFUxKr8af+7b8ZouU4PdmKEMkKk=";
10 };
11
12 nativeBuildInputs = [ bison cmake python3 ];
13 buildInputs = [ openssl readline bzip2 ];
14
15 postPatch = ''
16 substituteInPlace cmake/monetdb-packages.cmake --replace \
17 'get_os_release_info(LINUX_DISTRO LINUX_DISTRO_VERSION)' \
18 'set(LINUX_DISTRO "nixos")'
19 '';
20
21 postInstall = ''
22 rm $out/bin/monetdb_mtest.sh \
23 $out/bin/mktest.py \
24 $out/bin/sqlsample.php \
25 $out/bin/sqllogictest.py \
26 $out/bin/Mz.py \
27 $out/bin/Mtest.py \
28 $out/bin/sqlsample.pl \
29 $out/bin/malsample.pl \
30 $out/bin/Mconvert.py
31 '';
32
33 meta = with lib; {
34 description = "Open source database system";
35 homepage = "https://www.monetdb.org/";
36 license = licenses.mpl20;
37 platforms = platforms.unix;
38 maintainers = [ maintainers.StillerHarpo ];
39 };
40})